spSearchAvailable

CREATE  PROCEDURE dbo.spSearchAvailable(
    @ClientsID  int
)
AS
BEGIN
    SET NOCOUNT ON
    declare @SearchEnabled int
    select @SearchEnabled = SearchEnabled
    from Clients
    where id = @ClientsID
    set @SearchEnabled = isnull(@SearchEnabled,0)
    declare @IsFulltextInstalled int
    set @IsFulltextInstalled = isnull(fulltextserviceproperty('IsFulltextInstalled'),0)
    declare @IsFullTextEnabled int
    set @IsFullTextEnabled = isnull(convert(nvarchar(255),DATABASEPROPERTYEX(db_name(), 'IsFullTextEnabled')),0)
    declare @SearchTableExists int
    set @SearchTableExists = 0
    if @IsFulltextInstalled = 1
    begin
        declare @iResult int
        DECLARE @mycursor CURSOR
        EXEC @iResult = sp_help_fulltext_tables_cursor @mycursor OUTPUT, @table_name = 'Search'
        if @iResult = 0
        BEGIN
            DECLARE @Owner sysname, @Table sysname, @FTIndexName sysname, @ColumnID int, @Active int, @FTCatalogName sysname
            FETCH NEXT FROM @mycursor INTO @Owner, @Table, @FTIndexName, @ColumnID, @Active, @FTCatalogName
            if @@FETCH_STATUS = 0
                set @SearchTableExists = 1
            CLOSE @mycursor
        END
        DEALLOCATE @mycursor
    end
    if isnull(@SearchTableExists,0) > 0
        set @SearchTableExists = 1
    else
        set @SearchTableExists = 0
    declare @Result int
    set @Result = @SearchEnabled + @IsFulltextInstalled + @IsFullTextEnabled + @SearchTableExists
    SELECT @Result Result
END