UFN_GETVOLUNTEERASSIGNMENTS_BYDAY

CREATE function dbo.UFN_GETVOLUNTEERASSIGNMENTS_BYDAY 
(
    @VOLUNTEERID uniqueidentifier, 
    @DAY date, 
    @CURRENTAPPUSERID uniqueidentifier = null
)
returns @RESULTS table
(
    ID uniqueidentifier,
    JOBOCCURRENCEID uniqueidentifier,
    DESCRIPTION nvarchar(30),
    STARTTIME dbo.UDT_HOURMINUTE,
    ENDTIME dbo.UDT_HOURMINUTE,
    MATCH nvarchar(4)
)
as
begin

    insert into @RESULTS
    (
        ID,
        JOBOCCURRENCEID,
        DESCRIPTION,
        STARTTIME,
        ENDTIME,
        MATCH
    )
    select    
        VOLUNTEERASSIGNMENT.ID,
        JOBOCCURRENCE.ID JOBOCCURRENCEID,
        JOBOCCURRENCE.DESCRIPTION,
        JOBOCCURRENCE.STARTTIME,
        JOBOCCURRENCE.ENDTIME,
        cast(dbo.UFN_VOLUNTEER_JOBOCCURRENCE_GETMATCH(@VOLUNTEERID, JOBOCCURRENCE.ID, @DAY, @DAY) as nvarchar(3)) + '%'     
    from 
        dbo.VOLUNTEERASSIGNMENT
    inner join dbo.JOBOCCURRENCE 
        on dbo.VOLUNTEERASSIGNMENT.JOBOCCURRENCEID = dbo.JOBOCCURRENCE.ID
    inner join dbo.JOB
        on dbo.JOBOCCURRENCE.JOBID = dbo.JOB.ID
    where VOLUNTEERASSIGNMENT.VOLUNTEERID = @VOLUNTEERID
            and VOLUNTEERASSIGNMENT.DATE = @DAY
            and (dbo.UFN_SITEALLOWEDFORUSER(@CURRENTAPPUSERID,JOBOCCURRENCE.SITEID) = 1)
            and (dbo.UFN_SITEALLOWEDFORUSER(@CURRENTAPPUSERID,JOB.SITEID) = 1)
    order by JOBOCCURRENCE.DESCRIPTION;

    return
end