UFN_TRANSLATIONFUNCTION_CREDIT

CREATE function dbo.UFN_TRANSLATIONFUNCTION_CREDIT 
(
    @ID uniqueidentifier
) 
returns nvarchar(100)
as begin
    declare @DESCRIPTION nvarchar(100);
    declare @SALESORDERID uniqueidentifier;
    declare @SEQUENCEID int;

    select
        @DESCRIPTION = FT.TYPE + ' - ' + convert(nvarchar(15), FT.TRANSACTIONAMOUNT),
        @SALESORDERID = isnull(SALESORDER.ID, EXT.SALESORDERID),
        @SEQUENCEID = SALESORDER.SEQUENCEID
    from
        dbo.FINANCIALTRANSACTION as FT
    inner join
        dbo.CREDIT_EXT as EXT on EXT.ID = FT.ID
    left outer join
        dbo.SALESORDER on SALESORDER.REVENUEID = FT.PARENTID
    where
        FT.ID = @ID;

    if @SALESORDERID is not null begin
        if @SEQUENCEID is null begin
            select @SEQUENCEID = SEQUENCEID from dbo.SALESORDER where ID = @SALESORDERID;
        end

        set @DESCRIPTION += ', ' + dbo.UFN_REVENUE_TRANSACTIONTYPECODE_GETDESCRIPTION(5) /* Order */ + ': ' + convert(nvarchar(20), @SEQUENCEID);
    end

    return @DESCRIPTION;
end