USP_AMPROIMPORT_COMMITPURCHASEAFTERDETAIL

            CREATE procedure dbo.USP_AMPROIMPORT_COMMITPURCHASEAFTERDETAIL
            (
                @REVENUEID uniqueidentifier,
                @PDACCOUNTSYSTEMID uniqueidentifier,
                @CHANGEAGENTID uniqueidentifier,
                @CHANGEDATE datetime
            )
            as
            set nocount on;

            declare @CONSTITUENTID uniqueidentifier = null;
            declare @REVENUEDATE datetime = null;
            declare @REVENUEAMOUNT money = null;
            declare @DONATIONAMOUNT money = null;
            declare @RECEIPTAMOUNT money = null;

            select
                @CONSTITUENTID = CONSTITUENTID, @REVENUEDATE = DATE, @REVENUEAMOUNT = AMOUNT, @RECEIPTAMOUNT = RECEIPTAMOUNT
            from dbo.REVENUE 
            where ID = @REVENUEID;

            select 
                @DONATIONAMOUNT = sum(FINANCIALTRANSACTIONLINEITEM.BASEAMOUNT)
            from 
                dbo.FINANCIALTRANSACTIONLINEITEM
            where
                FINANCIALTRANSACTIONLINEITEM.DELETEDON is null
                and FINANCIALTRANSACTIONID = @REVENUEID and TYPECODE = 0;

            declare @MGSPLITS xml;
            select @MGSPLITS = 
                (
                    select 
                        sum(FINANCIALTRANSACTIONLINEITEM.BASEAMOUNT) AMOUNT, 
                        REVENUESPLIT_EXT.DESIGNATIONID, 
                        0 as TYPECODE
                    from 
                        dbo.FINANCIALTRANSACTIONLINEITEM
                        inner join dbo.REVENUESPLIT_EXT on REVENUESPLIT_EXT.ID = FINANCIALTRANSACTIONLINEITEM.ID
                    where 
                        FINANCIALTRANSACTIONLINEITEM.FINANCIALTRANSACTIONID = @REVENUEID
                        and FINANCIALTRANSACTIONLINEITEM.DELETEDON is null
                        and REVENUESPLIT_EXT.TYPECODE = 0
                    group by 
                        REVENUESPLIT_EXT.DESIGNATIONID
                    for xml raw('ITEM'),type,elements,root('SPLITS'),binary base64
                );

            if dbo.UFN_MATCHINGGIFTPREFERENCE_AUTOADDMG() > 0
                exec USP_MATCHINGGIFTPLEDGE_AUTOADD @CONSTITUENTID, @CHANGEAGENTID, @REVENUEID, @REVENUEDATE, @DONATIONAMOUNT, @RECEIPTAMOUNT, @MGSPLITS;

            if dbo.UFN_MATCHINGGIFTPREFERENCE_AUTOADDSPOUSEMG() > 0
                exec USP_MATCHINGGIFTPLEDGE_AUTOADDFROMSPOUSE @CONSTITUENTID, @CHANGEAGENTID, @REVENUEID, @REVENUEDATE, @DONATIONAMOUNT, @RECEIPTAMOUNT, @MGSPLITS;


            if @PDACCOUNTSYSTEMID is null
                set @PDACCOUNTSYSTEMID = '4B121C2C-CCE6-440D-894C-EA0DEF80D50B';

            exec dbo.USP_PDACCOUNTSYSTEM_LINKTOREVENUE
                @ID = @REVENUEID,
                @PDACCOUNTSYSTEMID = @PDACCOUNTSYSTEMID,
                @CHANGEDATE = @CHANGEDATE,
                @CHANGEAGENTID = @CHANGEAGENTID    

            exec dbo.USP_SAVE_REVENUEGLDISTRIBUTION @REVENUEID, @CHANGEAGENTID, @CHANGEDATE;
            exec dbo.USP_SAVE_AUCTIONPURCHASEGLDISTRIBUTION @REVENUEID, @CHANGEAGENTID, @CHANGEDATE, @PDACCOUNTSYSTEMID;

            exec dbo.USP_AMPROIMPORT_UPDATEPURCHASERECEIPTAMOUNTS @REVENUEID, @CHANGEAGENTID, @CHANGEDATE;