USP_CONSTITUENTRECOGNITIONDEFAULT_PREVENTDEFAULTING

Prevents revenue recognition from being created by default for the constituents.
Parameters

Parameter	Parameter Type	Mode
@ID	uniqueidentifier	INOUT
@SOURCECONSTITUENTID	uniqueidentifier	IN
@RECIPIENTCONSTITUENTID	uniqueidentifier	IN
@CHANGEAGENTID	uniqueidentifier	IN
Definition

Copy


            create procedure dbo.USP_CONSTITUENTRECOGNITIONDEFAULT_PREVENTDEFAULTING
            (
                @ID uniqueidentifier output,
                @SOURCECONSTITUENTID uniqueidentifier,
                @RECIPIENTCONSTITUENTID uniqueidentifier,
                @CHANGEAGENTID uniqueidentifier = null
            )
            as
                set nocount on

                declare @CURRENTDATE datetime
                set @CURRENTDATE = getdate()

                if @CHANGEAGENTID is null  
                    exec dbo.USP_CHANGEAGENT_GETORCREATECHANGEAGENT @CHANGEAGENTID output

                begin try
                    declare @EXISTINGID uniqueidentifier
                    select @EXISTINGID = ID from dbo.REVENUERECOGNITIONDEFAULT
                    where
                        SOURCECONSTITUENTID = @SOURCECONSTITUENTID and
                        RECIPIENTCONSTITUENTID = @RECIPIENTCONSTITUENTID

                    if @EXISTINGID is not null
                    begin
                        set @ID = @EXISTINGID

                        update dbo.REVENUERECOGNITIONDEFAULT set
                            PREVENTRECOGNITIONSDEFAULTING = 1,
                            MATCHFACTOR = 0,
                            STARTDATE = null,
                            ENDDATE = null,
                            DATECHANGED = @CURRENTDATE,
                            CHANGEDBYID = @CHANGEAGENTID
                        where ID = @ID
                    end
                    else
                    begin
                        if @ID is null
                            set @ID = newid()

                        insert into dbo.REVENUERECOGNITIONDEFAULT
                        (
                            SOURCECONSTITUENTID,
                            RECIPIENTCONSTITUENTID,
                            MATCHFACTOR,
                            PREVENTRECOGNITIONSDEFAULTING,
                            ADDEDBYID,
                            CHANGEDBYID,
                            DATEADDED,
                            DATECHANGED
                        )
                        values
                        (
                            @SOURCECONSTITUENTID,
                            @RECIPIENTCONSTITUENTID,
                            0,
                            1,
                            @CHANGEAGENTID,
                            @CHANGEAGENTID,
                            @CURRENTDATE,
                            @CURRENTDATE
                        )
                    end

                    exec dbo.USP_HOUSEHOLDRECOGNITIONSETTINGS_OVERRIDEIFNEEDED @SOURCECONSTITUENTID, @RECIPIENTCONSTITUENTID, @CHANGEAGENTID
                end try
                begin catch
                    exec dbo.USP_RAISE_ERROR;
                    return 1;
                end catch