USP_DATABASESPACEUSED_TOPNAUDIT

CREATE procedure dbo.[USP_DATABASESPACEUSED_TOPNAUDIT]
(
  @MAXROWS integer = 20,
  @ORDERBY tinyint = 0
)
as begin
  set nocount on;

  with [DATA] as (
    select
      [DATABASESPACEUSED].[NAME] as [NAMEAUDIT],
      substring([DATABASESPACEUSED].[NAME], 1, len([DATABASESPACEUSED].[NAME]) - 5) as [NAME],
      [DATABASESPACEUSED].[ROWS],
      [DATABASESPACEUSED].[RESERVEDKB],
      [DATABASESPACEUSED].[DATAKB],
      [DATABASESPACEUSED].[INDEXKB],
      [DATABASESPACEUSED].[UNUSEDKB],
      [DATABASESPACEUSED].[TABLECATALOGID]
    from dbo.[DATABASESPACEUSED]
    where [DATABASESPACEUSED].[TYPECODE] = 6
  )
  select top (@MAXROWS)
    [DATA].[NAMEAUDIT],
    [DATA].[NAME],
    isnull([RECORDTYPE].[NAME], '') as [RECORDTYPENAME],
    dbo.[UFN_AUDITENABLED]([DATA].[NAME]) as [AUDITINGENABLED],
    [DATA].[ROWS],
    [DATA].[RESERVEDKB],
    [DATA].[DATAKB],
    [DATA].[INDEXKB],
    [DATA].[UNUSEDKB],
    [DATA].[TABLECATALOGID],
    [RECORDTYPE].[ID] as [RECORDTYPEID]
  from [DATA]
  left outer join dbo.[RECORDTYPE] on [RECORDTYPE].[BASETABLENAME] = [DATA].[NAME]
  order by case @ORDERBY when 0 then [DATA].[RESERVEDKB] when 1 then [DATA].[DATAKB] when 2 then [DATA].[INDEXKB] when 3 then [DATA].[UNUSEDKB] end desc;

  return 0;
end