USP_DATAFORMTEMPLATE_ADD_IMPORTSOURCESFTP

Parameters

Parameter	Parameter Type	Mode
@ID	uniqueidentifier	INOUT
@CHANGEAGENTID	uniqueidentifier	IN
@NAME	nvarchar(100)	IN
@URL	nvarchar(255)	IN
@PORT	int	IN
@SITEID	uniqueidentifier	IN
@USERNAME	nvarchar(255)	IN
@PASSWORD	nvarchar(200)	IN
@URLLIST	nvarchar(255)	IN

Definition

Copy


CREATE procedure dbo.USP_DATAFORMTEMPLATE_ADD_IMPORTSOURCESFTP
(
    @ID uniqueidentifier = null output,
    @CHANGEAGENTID uniqueidentifier = null,
    @NAME nvarchar(100) = '',
    @URL nvarchar(255) = '',
    @PORT int = 22,
    @SITEID uniqueidentifier = null,
    @USERNAME nvarchar(255) = '',
    @PASSWORD nvarchar(200) = '',
    @URLLIST nvarchar(255) = ''
)
as

set nocount on;

if @ID is null
    set @ID = newid()

if @CHANGEAGENTID is null  
    exec dbo.USP_CHANGEAGENT_GETORCREATECHANGEAGENT @CHANGEAGENTID output

declare @CURRENTDATE datetime
set @CURRENTDATE = getdate();

declare @URLPATH nvarchar(255)

if (dbo.UFN_INSTALLEDPRODUCTS_PRODUCTIS('bb1c17bc-9e0b-4683-b490-ee40d511fa05') = 1) and /* basic program */
                    (dbo.UFN_INSTALLEDPRODUCTS_PRODUCTIS('3117D2C8-7F46-42F2-ABEB-B654F2F63046') = 0) /* Enterprise is not installed */
    Begin
        set @URLPATH = @URLLIST;
    End
    else
    Begin
        set @URLPATH = @URL;
    End

--open the symmetric key for encryption
exec dbo.USP_GET_KEY_ACCESS;

begin try
    insert into dbo.IMPORTSOURCE
        (ID, NAME, URLORPATH, PORT, SITEID, USERNAME, PASSWORD, IMPORTSOURCETYPECODE, ADDEDBYID, CHANGEDBYID, DATEADDED, DATECHANGED)
    values
        (@ID, @NAME, @URLPATH, @PORT, @SITEID, @USERNAME, EncryptByKey(Key_GUID('sym_BBInfinity'),@PASSWORD), 0, @CHANGEAGENTID, @CHANGEAGENTID, @CURRENTDATE, @CURRENTDATE)

    close symmetric key sym_BBInfinity;
end try

begin catch
    exec dbo.USP_RAISE_ERROR
    close symmetric key sym_BBInfinity;
    return 1
end catch

return 0