USP_DATAFORMTEMPLATE_EDIT_CONSTITUENTMATCHINGSETTINGS_2

create procedure dbo.USP_DATAFORMTEMPLATE_EDIT_CONSTITUENTMATCHINGSETTINGS_2
(
    @CHANGEAGENTID uniqueidentifier = null,
    @AUTOMATCHTHRESHOLD int,
    @OVERALLMATCHTHRESHOLDBATCH int,
    @OVERALLMATCHTHRESHOLD int,
    @AUTOMATCHTHRESHOLDMICROSITE int,
    @OVERALLMATCHTHRESHOLDMICROSITE int
)
as
    set nocount on;

    if @CHANGEAGENTID is null  
        exec dbo.USP_CHANGEAGENT_GETORCREATECHANGEAGENT @CHANGEAGENTID output

    declare @CURRENTDATE datetime
    set @CURRENTDATE = getdate()

    begin try
        update dbo.CONSTITUENTDUPLICATESEARCHSETTINGS set
            AUTOMATCHTHRESHOLD = @AUTOMATCHTHRESHOLD,
            OVERALLMATCHTHRESHOLDBATCH = @OVERALLMATCHTHRESHOLDBATCH,
            OVERALLMATCHTHRESHOLD = @OVERALLMATCHTHRESHOLD,
            CHANGEDBYID = @CHANGEAGENTID,
            DATECHANGED = @CURRENTDATE
        where TRANSACTIONTYPE = 'Default Criteria'  

        if @@ROWCOUNT = 0
            insert into dbo.CONSTITUENTDUPLICATESEARCHSETTINGS
            (
                AUTOMATCHTHRESHOLD,
                OVERALLMATCHTHRESHOLDBATCH,
                OVERALLMATCHTHRESHOLD,
                ROUTINENAME,
                LEFTPOSTCODECOUNT,
                DATEADDED, DATECHANGED, ADDEDBYID, CHANGEDBYID
            )
            values
            (
                @AUTOMATCHTHRESHOLD,
                @OVERALLMATCHTHRESHOLDBATCH,
                @OVERALLMATCHTHRESHOLD,

                -- Default values
                'UFN_CONSTITUENT_GETFUZZYDUPLICATES',
                3,
                @CURRENTDATE, @CURRENTDATE, @CHANGEAGENTID, @CHANGEAGENTID
            )

        update dbo.CONSTITUENTDUPLICATESEARCHSETTINGS set
            AUTOMATCHTHRESHOLD = @AUTOMATCHTHRESHOLDMICROSITE,
            OVERALLMATCHTHRESHOLD = @OVERALLMATCHTHRESHOLDMICROSITE,
            CHANGEDBYID = @CHANGEAGENTID,
            DATECHANGED = @CURRENTDATE
        where TRANSACTIONTYPE2CODE = 7 --Microsite Anonymous User

        if @@ROWCOUNT = 0
            insert into dbo.CONSTITUENTDUPLICATESEARCHSETTINGS
            (
                ID,
                AUTOMATCHTHRESHOLD,
                OVERALLMATCHTHRESHOLDBATCH,
                OVERALLMATCHTHRESHOLD,
                ROUTINENAME,
                LEFTPOSTCODECOUNT,
                TRANSACTIONTYPE2CODE,
                DATEADDED, DATECHANGED, ADDEDBYID, CHANGEDBYID
            )
            values
            (
                '7BDE63AA-73B8-4A31-BE9F-82D92B67E2F4',
                @AUTOMATCHTHRESHOLDMICROSITE,
                @OVERALLMATCHTHRESHOLDMICROSITE,
                @OVERALLMATCHTHRESHOLDMICROSITE,

                -- Default values
                'UFN_CONSTITUENT_GETFUZZYDUPLICATES',
                3,
                7, --Microsite Anonymous User
                @CURRENTDATE, @CURRENTDATE, @CHANGEAGENTID, @CHANGEAGENTID
            )

            --Update the batch template and the import processes where the global match settings are used. 
      update dbo.BATCHTEMPLATE set 
        AUTOMATCHTHRESHOLD= @AUTOMATCHTHRESHOLD,
        OVERALLMATCHTHRESHOLD = @OVERALLMATCHTHRESHOLDBATCH,
        CHANGEDBYID = @CHANGEAGENTID,
        DATECHANGED = @CURRENTDATE
      where USEGLOBALMATCHSETTINGS = 1;

      update dbo.IMPORTPROCESS set
        AUTOMATCHTHRESHOLD=@AUTOMATCHTHRESHOLD,
        OVERALLMATCHTHRESHOLD = @OVERALLMATCHTHRESHOLDBATCH,
        CHANGEDBYID = @CHANGEAGENTID,
        DATECHANGED = @CURRENTDATE
    from dbo.BATCHTEMPLATE where
    IMPORTPROCESS.BATCHTEMPLATEID = BATCHTEMPLATE.ID
    and USEGLOBALMATCHSETTINGS=1 and USEBATCHTEMPLATEMATCHSETTINGS = 1;

    end try
    begin catch
        exec dbo.USP_RAISE_ERROR
        return 1
    end catch

return 0;