USP_DATAFORMTEMPLATE_EDIT_CRM_BBPAY_TEMPLATE_4

create procedure dbo.USP_DATAFORMTEMPLATE_EDIT_CRM_BBPAY_TEMPLATE_4
(
    @ID uniqueidentifier,
    @CHANGEAGENTID uniqueidentifier = null,
    @HTMLSOURCE nvarchar(max),
    @CSSSOURCE nvarchar(max),
    @IMAGEPLACEHOLDERS xml,
    @CLIENTSITESID integer,
    @SITECONTENTID integer,
    @SITEPAGEID integer,
    @DELIVERYCHANNELID uniqueidentifier ,
    @ENVIRONMENTTEMPLATEID uniqueidentifier

)
as

set nocount on;

if @CHANGEAGENTID is null
    exec dbo.USP_CHANGEAGENT_GETORCREATECHANGEAGENT @CHANGEAGENTID output

-- these integer FKs can still be null for Microsite templates, which are not site page/part specific. guard against 0's passed in from bbappfx calls.
if @SITECONTENTID <= 0
    set @SITECONTENTID = null;

if @SITEPAGEID <= 0
    set @SITEPAGEID = null;

begin try
    -- handle updating the data
    update dbo.CRMBBPAYTEMPLATE set
        HTMLSOURCE = @HTMLSOURCE,
        CSSSOURCE = @CSSSOURCE,
        IMAGEPLACEHOLDERS = @IMAGEPLACEHOLDERS,
        CLIENTSITESID = @CLIENTSITESID,

        CHANGEDBYID = @CHANGEAGENTID,
        DATECHANGED = getdate(),
        SITECONTENTID = @SITECONTENTID,
        SITEPAGEID = @SITEPAGEID,
        DELIVERYCHANNELID = @DELIVERYCHANNELID
    where 
        ID = @ID;

    if @ENVIRONMENTTEMPLATEID is not null and not exists(select 1 from dbo.BBPAYENVIRONMENTTEMPLATE where ID = @ENVIRONMENTTEMPLATEID)
    begin
      declare @ENVIRONMENTID uniqueidentifier
      select @ENVIRONMENTID = ID from dbo.CRMBBENVIRONMENT where ISACTIVE = 1

    -- insert data into Environment Template table as well with the new generated @ID and the active environment.   
      insert into dbo.BBPAYENVIRONMENTTEMPLATE(ID,ENVIRONMENTID,TEMPLATEID,ADDEDBYID,CHANGEDBYID)
      values(@ENVIRONMENTTEMPLATEID,@ENVIRONMENTID,@ID,@CHANGEAGENTID,@CHANGEAGENTID)
    end 
end try
begin catch
    exec dbo.USP_RAISE_ERROR
    return 1
end catch

return 0;