USP_DATAFORMTEMPLATE_EDIT_MKTMEMBERSHIPMAILINGTEMPLATE

The save procedure used by the edit dataform template "Membership Renewal Effort Template Edit Form".

Parameters

Parameter	Parameter Type	Mode	Description
@ID	uniqueidentifier	IN	The input ID parameter indicating the ID of the record being edited.
@CURRENTAPPUSERID	uniqueidentifier	IN	Input parameter indicating the ID of the current user.
@CHANGEAGENTID	uniqueidentifier	IN	Input parameter indicating the ID of the change agent invoking the procedure.
@CODE	nvarchar(10)	IN	Code
@NAME	nvarchar(50)	IN	Name
@DESCRIPTION	nvarchar(255)	IN	Description
@SITEID	uniqueidentifier	IN	Site
@SOURCECODEID	uniqueidentifier	IN	Source code
@ITEMLIST	xml	IN	Items
@EXCLUSIONDATETYPECODE	tinyint	IN	Consider exclusions as of
@EXCLUSIONASOFDATE	datetime	IN	Consider exclusions as of
@EXCLUDEDECEASED	bit	IN	Exclude deceased constituents
@EXCLUDEINACTIVE	bit	IN	Exclude inactive constituents
@EXCLUSIONS	xml	IN	Exclusions
@USEADDRESSPROCESSING	bit	IN	Use address processing?
@ADDRESSPROCESSINGOPTIONID	uniqueidentifier	IN	Address processing options
@NAMEFORMATPARAMETERID	uniqueidentifier	IN	Name format options
@ADDRESSPROCESSINGOPTIONSEASONALASOFDATETYPECODE	tinyint	IN	Consider seasonal addresses as of
@ADDRESSPROCESSINGOPTIONSEASONALASOFDATE	datetime	IN	Consider seasonal addresses as of

Definition

Copy



CREATE procedure dbo.[USP_DATAFORMTEMPLATE_EDIT_MKTMEMBERSHIPMAILINGTEMPLATE]
(
  @ID uniqueidentifier,
  @CURRENTAPPUSERID uniqueidentifier,
  @CHANGEAGENTID uniqueidentifier = null,
  @CODE nvarchar(10),
  @NAME nvarchar(50),
  @DESCRIPTION nvarchar(255),
  @SITEID uniqueidentifier,
  @SOURCECODEID uniqueidentifier,
  @ITEMLIST xml,
  @EXCLUSIONDATETYPECODE tinyint,
  @EXCLUSIONASOFDATE datetime,
  @EXCLUDEDECEASED bit,
  @EXCLUDEINACTIVE bit,
  @EXCLUSIONS xml,
  @USEADDRESSPROCESSING bit,
  @ADDRESSPROCESSINGOPTIONID uniqueidentifier,
  @NAMEFORMATPARAMETERID uniqueidentifier,
  @ADDRESSPROCESSINGOPTIONSEASONALASOFDATETYPECODE tinyint,
  @ADDRESSPROCESSINGOPTIONSEASONALASOFDATE datetime
)
as
  set nocount on;

  declare @CURRENTDATE datetime;
  declare @CURRENTSITEID uniqueidentifier;
  declare @OLDSOURCECODEID uniqueidentifier;
  declare @MEMBERSHIPMAILINGPROCESSID uniqueidentifier;

  if exists(select top 1 1 from dbo.[MKTMEMBERSHIPMAILINGTEMPLATERULE] where [MEMBERSHIPMAILINGTEMPLATEID] = @ID) or
     exists(select top 1 1 from dbo.[MKTMEMBERSHIPMAILINGTEMPLATESEED] where [MEMBERSHIPMAILINGTEMPLATEID] = @ID)
    begin
      select @CURRENTSITEID = [SITEID] from dbo.[MKTMEMBERSHIPMAILINGTEMPLATE] where [ID] = @ID;

      if (@CURRENTSITEID <> @SITEID or (@CURRENTSITEID is null and @SITEID is not null) or (@CURRENTSITEID is not null and @SITEID is null))
        begin
          raiserror('Site may not be changed on an membership renewal effort template that is in use or has dependencies.', 13, 1);
          return 1;
        end
    end

  begin try
    if @CHANGEAGENTID is null
      exec dbo.[USP_CHANGEAGENT_GETORCREATECHANGEAGENT] @CHANGEAGENTID output;

    select
      @OLDSOURCECODEID = [SOURCECODEID],
      @CURRENTDATE = getdate()
    from dbo.[MKTMEMBERSHIPMAILINGTEMPLATE]
    where [ID] = @ID;

    /* update the membership mailing template fields */
    update dbo.[MKTMEMBERSHIPMAILINGTEMPLATE] set
      [CODE] = @CODE,
      [NAME] = @NAME,
      [DESCRIPTION] = @DESCRIPTION,
      [SITEID] = @SITEID,
      [SOURCECODEID] = @SOURCECODEID,
      [USEADDRESSPROCESSING] = @USEADDRESSPROCESSING,
      [ADDRESSPROCESSINGOPTIONID] = @ADDRESSPROCESSINGOPTIONID,
      [NAMEFORMATPARAMETERID] = @NAMEFORMATPARAMETERID,
      [ADDRESSPROCESSINGOPTIONSEASONALASOFDATETYPECODE] = @ADDRESSPROCESSINGOPTIONSEASONALASOFDATETYPECODE,
      [ADDRESSPROCESSINGOPTIONSEASONALASOFDATE] = @ADDRESSPROCESSINGOPTIONSEASONALASOFDATE,
      [CHANGEDBYID] = @CHANGEAGENTID,
      [DATECHANGED] = @CURRENTDATE
    where [ID] = @ID;

    /* save the sourcecode parts */
    exec dbo.[USP_MKTMEMBERSHIPMAILINGTEMPLATESOURCECODEPART_GETITEMLIST_UPDATEFROMXML] @ID, @ITEMLIST, @CHANGEAGENTID, @CURRENTDATE;

    /* update any rule codes in this template with their base segment codes */
    if isnull(cast(@OLDSOURCECODEID as varchar(36)), '') <> isnull(cast(@SOURCECODEID as varchar(36)), '')
      update dbo.[MKTMEMBERSHIPMAILINGTEMPLATERULE] set
        [CODE] = (case when @SOURCECODEID is null then '' else [MKTSEGMENT].[CODE] end),
        [CHANGEDBYID] = @CHANGEAGENTID,
        [DATECHANGED] = @CURRENTDATE
      from dbo.[MKTMEMBERSHIPMAILINGTEMPLATERULE] as [RULE]
      inner join dbo.[MKTSEGMENT] on [MKTSEGMENT].[ID] = [RULE].[SEGMENTID]
      where [RULE].[MEMBERSHIPMAILINGTEMPLATEID] = @ID;

    /* save the contact rules/communication preferences for the membership mailing business process */
    select
      @MEMBERSHIPMAILINGPROCESSID = [ID]
    from
      dbo.[MKTMEMBERSHIPMAILINGPROCESS]
    where
      [MEMBERSHIPMAILINGTEMPLATEID] = @ID;

    exec dbo.[USP_BUSINESSPROCESSCOMMPREF_UPDATE]
      @CHANGEAGENTID = @CHANGEAGENTID,
      @BUSINESSPROCESSCATALOGID = '854A7703-89D1-4EF7-A7C6-B8836A887092',
      @BUSINESSPROCESSPARAMETERSETID = @MEMBERSHIPMAILINGPROCESSID,
      @EXCLUSIONDATETYPECODE = @EXCLUSIONDATETYPECODE,
      @EXCLUSIONASOFDATE = @EXCLUSIONASOFDATE,
      @EXCLUDEDECEASED = @EXCLUDEDECEASED,
      @EXCLUDEINACTIVE = @EXCLUDEINACTIVE,
      @EXCLUSIONS = @EXCLUSIONS,
      @CURRENTAPPUSERID = @CURRENTAPPUSERID;

  end try

  begin catch
    exec dbo.[USP_RAISE_ERROR];
    return 1;
  end catch

  return 0;