USP_DATAFORMTEMPLATE_EDIT_MKTSEGMENTATIONSEED_2

create procedure dbo.[USP_DATAFORMTEMPLATE_EDIT_MKTSEGMENTATIONSEED_2]
(
  @ID uniqueidentifier,
  @CHANGEAGENTID uniqueidentifier = null,
  @SEEDS xml
)
as
  set nocount on;

  declare @CURRENTDATE datetime;
  declare @SEEDID uniqueidentifier;
  declare @SELECTED bit;
  declare @SEGMENTATIONSEEDID uniqueidentifier;

  begin try
    if (select [ACTIVE] from dbo.[MKTSEGMENTATION] where [ID] = @ID) = 0
      exec dbo.[USP_MKTSEGMENTATION_CHECKACTIVATION] @ID;

    if @CHANGEAGENTID is null  
      exec dbo.[USP_CHANGEAGENT_GETORCREATECHANGEAGENT] @CHANGEAGENTID output;

    set @CURRENTDATE = getdate();

    declare SEEDCURSOR cursor local fast_forward for
      select [ID], [SELECTED]
      from dbo.[UFN_MKTSEGMENTATIONSEED_GETSEEDS_2_FROMITEMLISTXML](@SEEDS);

    open SEEDCURSOR;
    fetch next from SEEDCURSOR into @SEEDID, @SELECTED;

    while (@@FETCH_STATUS = 0)
      begin
        select @SEGMENTATIONSEEDID = [ID] 
        from dbo.[MKTSEGMENTATIONSEED] 
        where [SEGMENTATIONID] = @ID and [SEEDID] = @SEEDID;

        if @SELECTED = 0
          begin
            if @SEGMENTATIONSEEDID is not null
              exec dbo.[USP_MKTSEGMENTATIONSEED_DELETEBYID_WITHCHANGEAGENTID] @SEGMENTATIONSEEDID, @CHANGEAGENTID;
          end
        else
          begin
            if @SEGMENTATIONSEEDID is null
              insert into dbo.[MKTSEGMENTATIONSEED] (
                [ID],
                [SEGMENTATIONID],
                [SEEDID],
                [ADDEDBYID],
                [CHANGEDBYID],
                [DATEADDED],
                [DATECHANGED]
              ) values (
                newid(),
                @ID,
                @SEEDID,
                @CHANGEAGENTID,
                @CHANGEAGENTID,
                @CURRENTDATE,
                @CURRENTDATE
              );
          end

        set @SEGMENTATIONSEEDID = null;
        fetch next from SEEDCURSOR into @SEEDID, @SELECTED;
      end;

    close SEEDCURSOR;
    deallocate SEEDCURSOR;
  end try

  begin catch
    exec dbo.[USP_RAISE_ERROR];
    return 1;
  end catch

  return 0;