USP_DATAFORMTEMPLATE_EDIT_MKTSEGMENTATIONSEGMENT

CREATE procedure dbo.USP_DATAFORMTEMPLATE_EDIT_MKTSEGMENTATIONSEGMENT
(
  @ID uniqueidentifier,
  @CHANGEAGENTID uniqueidentifier = null,
  @SEGMENTID uniqueidentifier,
  @CODE nvarchar(10),
  @PACKAGEID uniqueidentifier,
  @PACKAGECODE nvarchar(10),
  @RESPONSERATE decimal(5,2),
  @GIFTAMOUNT money,
  @SAMPLESIZE int,
  @SAMPLESIZETYPECODE tinyint,
  @SAMPLESIZEMETHODCODE tinyint
)
as
  set nocount on;

  declare @SEGMENTATIONID uniqueidentifier;
  declare @ACTIVE bit;
  declare @OLDSEGMENTATIONPACKAGEID uniqueidentifier;
  declare @OLDPACKAGEID uniqueidentifier;
  declare @CURRENTDATE datetime;

  begin try
    select
      @ACTIVE = [MKTSEGMENTATION].[ACTIVE]
    from dbo.[MKTSEGMENTATIONSEGMENT]
    inner join dbo.[MKTSEGMENTATION] on [MKTSEGMENTATION].[ID] = [MKTSEGMENTATIONSEGMENT].[SEGMENTATIONID]
    where [MKTSEGMENTATIONSEGMENT].[ID] = @ID;

    if @ACTIVE = 0
      begin
        if @CHANGEAGENTID is null  
          exec dbo.[USP_CHANGEAGENT_GETORCREATECHANGEAGENT] @CHANGEAGENTID output;

        set @CURRENTDATE = GetDate();

        /* Grab the old packageID info before we save the segment */
        select 
          @SEGMENTATIONID = [SEG].[SEGMENTATIONID],
          @OLDSEGMENTATIONPACKAGEID = (select [PAK].[ID] from dbo.[MKTSEGMENTATIONPACKAGE] as [PAK] where [PAK].[SEGMENTATIONID] = [SEG].[SEGMENTATIONID] and [PAK].[PACKAGEID] = [SEG].[PACKAGEID]),
          @OLDPACKAGEID = [SEG].[PACKAGEID] 
        from dbo.[MKTSEGMENTATIONSEGMENT] as [SEG]
        where [SEG].[ID] = @ID;

        /* Save the segment */
        update dbo.[MKTSEGMENTATIONSEGMENT] set 
          [SEGMENTID] = @SEGMENTID,
          [CODE] = @CODE,
          [PACKAGEID] = @PACKAGEID,
          [RESPONSERATE] = @RESPONSERATE,
          [GIFTAMOUNT] = @GIFTAMOUNT,
          [SAMPLESIZE] = @SAMPLESIZE,
          [SAMPLESIZETYPECODE] = @SAMPLESIZETYPECODE,
          [SAMPLESIZEMETHODCODE] = @SAMPLESIZEMETHODCODE,
          [CHANGEDBYID] = @CHANGEAGENTID,
          [DATECHANGED] = @CURRENTDATE
        where [ID] = @ID;

        /* Save and update the package for the segment */
        if @OLDPACKAGEID <> @PACKAGEID
          begin
            /* Remove the old package, only if is not being used by any other segments and test segments */
            if not exists(select [ID] from dbo.[MKTSEGMENTATIONSEGMENT] where [SEGMENTATIONID] = @SEGMENTATIONID and [PACKAGEID] = @OLDPACKAGEID) and
               not exists(select [MKTSEGMENTATIONTESTSEGMENT].[ID] from dbo.[MKTSEGMENTATIONTESTSEGMENT] inner join dbo.[MKTSEGMENTATIONSEGMENT] on [MKTSEGMENTATIONSEGMENT].[ID] = [MKTSEGMENTATIONTESTSEGMENT].[SEGMENTID] where [MKTSEGMENTATIONSEGMENT].[SEGMENTATIONID] = @SEGMENTATIONID and [MKTSEGMENTATIONTESTSEGMENT].[PACKAGEID] = @OLDPACKAGEID)
              exec dbo.[USP_MKTSEGMENTATIONPACKAGE_DELETE] @OLDSEGMENTATIONPACKAGEID, @CHANGEAGENTID;

            /* Add the new package, only if it doesn't exist already */
            if not exists(select [ID] from dbo.[MKTSEGMENTATIONPACKAGE] where [SEGMENTATIONID] = @SEGMENTATIONID and [PACKAGEID] = @PACKAGEID)
              exec dbo.[USP_DATAFORMTEMPLATE_ADD_MKTSEGMENTATIONPACKAGE] null, @CHANGEAGENTID, @SEGMENTATIONID, @PACKAGEID;
          end

        declare @OLDCODE nvarchar(10);
        /* Update the package with the selected code */
        select @OLDCODE=coalesce([CODE],'') from dbo.[MKTPACKAGE] where [ID]=@PACKAGEID;
        if @OLDCODE<>@PACKAGECODE
          update dbo.[MKTPACKAGE] set [CODE]=@PACKAGECODE,[CHANGEDBYID]=@CHANGEAGENTID,[DATECHANGED]=@CURRENTDATE where [ID]=@PACKAGEID;

        /* Update the segment with the selected code */
        select @OLDCODE=coalesce([CODE],'') from dbo.[MKTSEGMENT] where [ID]=@SEGMENTID;
        if @OLDCODE<>@CODE
          update dbo.[MKTSEGMENT] set [CODE]=@CODE,[CHANGEDBYID]=@CHANGEAGENTID,[DATECHANGED]=@CURRENTDATE where [ID]=@SEGMENTID;
      end
  end try

  begin catch
    exec dbo.USP_RAISE_ERROR;
    return 1;
  end catch

  return 0;