USP_DATAFORMTEMPLATE_EDIT_REVENUEBATCHDUPLICATEAUTOMATCH

                    create procedure dbo.USP_DATAFORMTEMPLATE_EDIT_REVENUEBATCHDUPLICATEAUTOMATCH
                    (
                        @ID uniqueidentifier,
                        @CHANGEAGENTID uniqueidentifier = null,
                        @CONSTITUENTID uniqueidentifier
                    )
                    as

                        set nocount on;

                        if @CHANGEAGENTID is null  
                            exec dbo.USP_CHANGEAGENT_GETORCREATECHANGEAGENT @CHANGEAGENTID output

                        declare @CURRENTDATE datetime
                        set @CURRENTDATE = getdate()

                        begin try
                            declare @ORIGINALCONSTITUENTID uniqueidentifier
                            select
                                @ORIGINALCONSTITUENTID = CONSTITUENTID
                            from dbo.BATCHREVENUE
                            where ID = @ID

                            update dbo.BATCHREVENUERECOGNITION set
                                CONSTITUENTID = @CONSTITUENTID,
                                CHANGEDBYID = @CHANGEAGENTID,
                                DATECHANGED = @CURRENTDATE
                            where
                                BATCHREVENUEID = @ID and
                                CONSTITUENTID = @ORIGINALCONSTITUENTID

                            update dbo.BATCHREVENUEAPPLICATIONPLEDGE set
                                CONSTITUENTID = @CONSTITUENTID,
                                CHANGEDBYID = @CHANGEAGENTID,
                                DATECHANGED = @CURRENTDATE
                            from dbo.BATCHREVENUEAPPLICATIONPLEDGE
                            inner join dbo.BATCHREVENUEAPPLICATION on BATCHREVENUEAPPLICATIONPLEDGE.ID = BATCHREVENUEAPPLICATION.BATCHREVENUEAPPLICATIONPLEDGEID
                            where
                                BATCHREVENUEAPPLICATION.BATCHREVENUEID = @ID and
                                BATCHREVENUEAPPLICATIONPLEDGE.CONSTITUENTID = @ORIGINALCONSTITUENTID

                            declare @GIVESANONYMOUSLY bit
                            select
                                @GIVESANONYMOUSLY = GIVESANONYMOUSLY
                            from dbo.CONSTITUENT
                            where ID = @CONSTITUENTID

                            update dbo.BATCHREVENUE set
                                CONSTITUENTID = @CONSTITUENTID,
                                GIVENANONYMOUSLY = @GIVESANONYMOUSLY,
                                CHANGEDBYID = @CHANGEAGENTID,
                                DATECHANGED = @CURRENTDATE
                            where ID = @ID
                        end try
                        begin catch
                            exec dbo.USP_RAISE_ERROR
                            return 1
                        end catch

                    return 0;