USP_DATAFORMTEMPLATE_EDIT_SEPAMANDATE

create procedure dbo.USP_DATAFORMTEMPLATE_EDIT_SEPAMANDATE 
(
    @ID uniqueidentifier,
    @CHANGEAGENTID uniqueidentifier = null,
    @SIGNATUREDATE datetime,
    @LOOKUPID nvarchar(35),
    @OVERRIDELOOKUPID bit,
    @TYPECODE tinyint,
    @STATUSCODE tinyint
)
as
    set nocount on;

    if @CHANGEAGENTID is null  
        exec dbo.USP_CHANGEAGENT_GETORCREATECHANGEAGENT @CHANGEAGENTID output;

    declare @CURRENTDATE datetime;
    set @CURRENTDATE = getdate();

    begin try
        --Setup the override for the mandate lookup ID
        declare @CUSTOMIDENTIFIER nvarchar(35) = '';
        if @OVERRIDELOOKUPID = 1
        begin
            if @LOOKUPID is not null and @LOOKUPID <> ''
            begin
                set @CUSTOMIDENTIFIER = @LOOKUPID;
            end
            else
            begin
                raiserror('BBERR_MANDATELOOKUPID_CANNOTBENULLOREMPTY', 13, 1);
            end
        end

        -- handle updating the data
        update dbo.SEPAMANDATE 
        set
            SEPAMANDATE.CUSTOMIDENTIFIER = @CUSTOMIDENTIFIER,
            SEPAMANDATE.SIGNATUREDATE = @SIGNATUREDATE,
            SEPAMANDATE.TYPECODE = @TYPECODE,
            SEPAMANDATE.STATUSCODE = @STATUSCODE,
            SEPAMANDATE.CHANGEDBYID = @CHANGEAGENTID,
            SEPAMANDATE.DATECHANGED = @CURRENTDATE
        where 
            SEPAMANDATE.ID = @ID;

    end try
    begin catch
        exec dbo.USP_RAISE_ERROR;
        return 1;
    end catch

return 0;