USP_DATALIST_CREDITREFUND_EVENTREGISTRATIONS

CREATE procedure dbo.USP_DATALIST_CREDITREFUND_EVENTREGISTRATIONS
(
    @CREDITID uniqueidentifier
)
as
    set nocount on;

    select 
        CREDITITEMEVENTREGISTRATION.REGISTRANTID as REGISTRANTID,
        NF.NAME as REGISTRANTNAME,
        EVENT.NAME as EVENTNAME,
        EVENT.STARTDATE,
        EVENT.STARTTIME,
        sum((LI.QUANTITY * LI.UNITVALUE) - EXT.DISCOUNTS) as TOTAL
    from
        dbo.FINANCIALTRANSACTION as FT
    inner join
        dbo.FINANCIALTRANSACTIONLINEITEM as LI on LI.FINANCIALTRANSACTIONID = FT.ID
    inner join
        dbo.CREDITITEM_EXT as EXT on EXT.ID = LI.ID
    inner join
        dbo.CREDITITEMEVENTREGISTRATION on CREDITITEMEVENTREGISTRATION.ID = LI.ID
    inner join
        dbo.REGISTRANT on REGISTRANT.ID = CREDITITEMEVENTREGISTRATION.REGISTRANTID
    inner join
        dbo.EVENT on EVENT.ID = REGISTRANT.EVENTID
    outer apply
        dbo.UFN_CONSTITUENT_DISPLAYNAME(REGISTRANT.CONSTITUENTID) as NF
    where
        FT.ID = @CREDITID
        and FT.TYPECODE = 23  -- Refund

    group by
        EXT.GROUPID,
        CREDITITEMEVENTREGISTRATION.REGISTRANTID,
        NF.NAME,
        EVENT.NAME,
        EVENT.STARTDATE,
        EVENT.STARTTIME

    return 0;