USP_DATALIST_EVENTINVITEES

                CREATE procedure dbo.USP_DATALIST_EVENTINVITEES
                (
                    @EVENTID uniqueidentifier,
                    @REGISTERED tinyint = null,
                    @DECLINED tinyint = null
                )
                as
                    set nocount on;

                    select
                        INVITEE.ID,
                        INVITEE.CONSTITUENTID,
                        INVITATION.ID INVITATIONID,
                        INVITATION.NAME INVITATION,
                        dbo.UFN_CONSTITUENT_BUILDNAME(INVITEE.CONSTITUENTID) CONSTITUENTNAME,
                        cast
                        (
                            case
                                when REGISTRANT.CONSTITUENTID is null then 0
                                else 1
                            end
                            as bit
                        ) [REGISTERED],
                        case
                            when REGISTRANT.CONSTITUENTID is null then N'Not registered'
                            else N'Registered'
                        end [REGISTEREDCAPTION],
                        INVITEE.DECLINED,
                        case INVITEE.DECLINED
                            when 0 then 'Not declined'
                            else 'Declined'
                        end [DECLINEDCAPTION]
                    from
                        dbo.INVITEE
                        inner join dbo.INVITATION
                            on INVITEE.INVITATIONID = INVITATION.ID
                        left join dbo.REGISTRANT
                            on INVITEE.CONSTITUENTID = REGISTRANT.CONSTITUENTID
                            and INVITEE.EVENTID = REGISTRANT.EVENTID
                    where
                        INVITEE.EVENTID = @EVENTID
                        and
                        (
                            @REGISTERED is null
                            or
                            (
                                @REGISTERED = 0
                                and
                                REGISTRANT.CONSTITUENTID is null
                            )
                            or
                            (
                                @REGISTERED = 1
                                and
                                REGISTRANT.CONSTITUENTID is not null
                            )
                        )
                        and
                        (
                            @DECLINED is null
                            or
                            @DECLINED = INVITEE.DECLINED
                        )
                    order by
                        INVITATION, CONSTITUENTNAME;