USP_DATALIST_EVENTTASKS2

                CREATE procedure dbo.USP_DATALIST_EVENTTASKS2(
                    @EVENTID uniqueidentifier,
                    @DATEFILTER tinyint = 0, 
                    @INCLUDECOMPLETEDTASKS bit = 0,
                    @INCLUDESUBEVENTS bit = 0,
                    @CURRENTAPPUSERID uniqueidentifier = null
                )
                as
                    set nocount on;

                    declare @DATE datetime
                    declare @ENDDATE datetime

                    set @DATE = getdate();

                    if @DATEFILTER = 0        -- all

                        begin
                            set @ENDDATE = null
                        end

                    if @DATEFILTER = 1        -- this week

                        begin
                            set @ENDDATE = dbo.UFN_DATE_THISWEEK_LASTDAY(@DATE, 0)
                        end

                    if @DATEFILTER = 2        -- this month

                        begin
                            set @ENDDATE = dbo.UFN_DATE_THISMONTH_LASTDAY(@DATE, 0)
                        end

                    if @DATEFILTER = 3        -- this quarter

                        begin
                            set @ENDDATE = dbo.UFN_DATE_THISQUARTER_LASTDAY(@DATE, 0)
                        end            

                    select 
                        EVENTTASK.ID,
                        case when EVENTTASK.STATUSCODE = 0 and datediff(day, @DATE, EVENTTASK.COMPLETEBYDATE) < 0 then 
                            1
                        else 
                            0
                        end,
                        case when EVENTTASK.STATUSCODE = 0 and datediff(day, @DATE, EVENTTASK.COMPLETEBYDATE) < 0 then 
                            'RES:warning'
                        when EVENTTASK.STATUSCODE = 1 then 
                            'RES:checkmark'
                        else 
                            'RES:lv_spacer'
                        end,                                    
                        EVENTTASK.NAME,
                        OWNERS.NAME,
                        EVENTTASK.COMPLETEBYDATE,
                        EVENTTASK.DATECOMPLETED,
                        EVENTTASK.STATUSCODE, 
                        EVENTTASK.COMMENT,
                        EVENTS.NAME as [EVENTNAME]
                    from 
                        dbo.UFN_CHILDEVENTSWITHSITEACCESS(@EVENTID, @CURRENTAPPUSERID) EVENTS
                    inner join
                        dbo.EVENTTASK on EVENTTASK.EVENTID = EVENTS.ID
                    outer apply dbo.UFN_CONSTITUENT_DISPLAYNAME(EVENTTASK.OWNERID) OWNERS
                    where 
                        (EVENTS.ID = @EVENTID or @INCLUDESUBEVENTS = 1) and
                        ((@ENDDATE is null) or (EVENTTASK.COMPLETEBYDATE <= @ENDDATE)) and
                        ((EVENTTASK.STATUSCODE = 0) or (@INCLUDECOMPLETEDTASKS = 1))                  
                    order by
                        EVENTS.LEVEL asc,
                        EVENTS.NAME asc,
                        EVENTTASK.STATUS asc,
                        EVENTTASK.COMPLETEBYDATE asc,
                        EVENTTASK.DATECOMPLETED asc