USP_DATALIST_JOBDOCUMENTATION

                CREATE procedure dbo.USP_DATALIST_JOBDOCUMENTATION 
                (
                    @JOBID uniqueidentifier = null,
                    @DOCUMENTATIONTYPECODE tinyint = null,
                    @TITLE nvarchar(50) = ''
                )
                as
                    set nocount on;

                    select    
                        JOBNOTE.ID,
                        'C8E7C0F0-00FE-465E-A0A9-EB1122512451' as [VIEWFORMID],
                        0 as [DOCUMENTATIONTYPECODE],
                        null as [MEDIAURL],
                        null as [FILENAME],
                        null as [FILEFIELDID],
                        'Note' as [DOCUMENTATIONTYPE],
                        JOBNOTE.DATEENTERED,
                        JOBNOTETYPECODE.DESCRIPTION as [TYPE],
                        JOBNOTE.TITLE,
                        NF.NAME
                    from
                        dbo.JOBNOTE
                    inner join
                        dbo.JOBNOTETYPECODE
                    on
                        JOBNOTETYPECODE.ID = JOBNOTE.JOBNOTETYPECODEID
                    outer apply dbo.UFN_CONSTITUENT_DISPLAYNAME(JOBNOTE.AUTHORID) NF
                    where 
                        JOBNOTE.JOBID = @JOBID and
                        (@DOCUMENTATIONTYPECODE is null or @DOCUMENTATIONTYPECODE = 0) and
                        (@TITLE = '' or JOBNOTE.TITLE like @TITLE + '%')

                    union all

                    select    
                        JOBMEDIALINK.ID,
                        '52F72382-D429-4E7B-9E9A-8EA434103C71' as [VIEWFORMID],
                        1 as [DOCUMENTATIONTYPECODE],
                        JOBMEDIALINK.MEDIAURL,
                        null,
                        null,
                        'Media link' as [DOCUMENTATIONTYPE],
                        JOBMEDIALINK.DATEENTERED,
                        JOBMEDIALINKTYPECODE.DESCRIPTION as [TYPE],
                        JOBMEDIALINK.TITLE,
                        NF.NAME
                    from
                        dbo.JOBMEDIALINK
                    inner join
                        dbo.JOBMEDIALINKTYPECODE
                    on
                        JOBMEDIALINKTYPECODE.ID = JOBMEDIALINK.JOBMEDIALINKTYPECODEID
                    outer apply dbo.UFN_CONSTITUENT_DISPLAYNAME(JOBMEDIALINK.AUTHORID) NF
                    where 
                        JOBMEDIALINK.JOBID = @JOBID and
                        (@DOCUMENTATIONTYPECODE is null or @DOCUMENTATIONTYPECODE = 1) and
                        (@TITLE = '' or JOBMEDIALINK.TITLE like @TITLE + '%')

                    union all

                    select    
                        JOBATTACHMENT.ID,
                        '0B1F67E7-B69B-4198-8407-57872E47CBE6' as [VIEWFORMID],
                        2 as [DOCUMENTATIONTYPECODE],
                        null,
                        JOBATTACHMENT.FILENAME,
                        'FILE',
                        'Attachment' as [DOCUMENTATIONTYPE],
                        JOBATTACHMENT.DATEENTERED,
                        JOBATTACHMENTTYPECODE.DESCRIPTION as [TYPE],
                        JOBATTACHMENT.TITLE,
                        NF.NAME
                    from
                        dbo.JOBATTACHMENT
                    inner join
                        dbo.JOBATTACHMENTTYPECODE
                    on
                        JOBATTACHMENTTYPECODE.ID = JOBATTACHMENT.JOBATTACHMENTTYPECODEID
                    outer apply dbo.UFN_CONSTITUENT_DISPLAYNAME(JOBATTACHMENT.AUTHORID) NF
                    where 
                        JOBATTACHMENT.JOBID = @JOBID and
                        (@DOCUMENTATIONTYPECODE is null or @DOCUMENTATIONTYPECODE = 2) and
                        (@TITLE = '' or JOBATTACHMENT.TITLE like @TITLE + '%')

                    order by
                        DATEENTERED desc;