USP_DATALIST_NEWPAGES

CREATE procedure dbo.USP_DATALIST_NEWPAGES
(
    @SHOWCODE smallint = 1,
    @RECORDTYPEID uniqueidentifier = null,
    @INCLUDEALLPRODUCTS bit = 0,
    @DATAWINDOWOPEN datetime = null,
    @DATAWINDOWCLOSE datetime = null
)
as
    set nocount on;

    declare @STARTDATE datetime;
    declare @ENDDATE datetime;

    exec dbo.USP_APPCATALOG_GETNEWFEATURESTARTENDDATES @SHOWCODE, @STARTDATE output, @ENDDATE output;

    with xmlnamespaces ('bb_appfx_pagedefinition' as tns, 'bb_appfx_commontypes' as common)
    select P.ID,
           P.UINAME as NAME,
           P.DESCRIPTION,
           P.PAGEDEFINITIONSPEC.value('(tns:PageDefinitionSpec/@Author)[1]', 'nvarchar(500)'),
           coalesce(RT.NAME, ''),
           P.DATEADDED,
           dbo.UFN_INSTALLEDPRODUCTS_OPTIONALPRODUCTSINSTALLED(P.PAGEDEFINITIONSPEC.query('tns:PageDefinitionSpec/common:InstalledProductList'))
    from dbo.PAGEDEFINITIONCATALOG as P
         left join dbo.RECORDTYPE as RT on P.CONTEXTRECORDTYPEID = RT.ID
    where ((@STARTDATE is null) or (P.DATEADDED >= @STARTDATE)) and
          ((@ENDDATE is null) or (P.DATEADDED <= @ENDDATE)) and
          ((@RECORDTYPEID is null) or (P.CONTEXTRECORDTYPEID = @RECORDTYPEID)) and
          ((@INCLUDEALLPRODUCTS = 1) or (1 = dbo.UFN_INSTALLEDPRODUCTS_OPTIONALPRODUCTSINSTALLED(P.PAGEDEFINITIONSPEC.query('/*/common:InstalledProductList')))) and
          ((@DATAWINDOWOPEN is null) or (P.DATEADDED >= @DATAWINDOWOPEN)) and 
          ((@DATAWINDOWCLOSE is null) or (P.DATEADDED < @DATAWINDOWCLOSE))
    order by P.DATEADDED DESC