USP_DATALIST_NEWSMARTFIELDS

CREATE procedure dbo.USP_DATALIST_NEWSMARTFIELDS
(
    @SHOWCODE smallint = 1,
    @RECORDTYPEID uniqueidentifier = null,
    @INCLUDEALLPRODUCTS bit = 0,
    @DATAWINDOWOPEN datetime = null,
    @DATAWINDOWCLOSE datetime = null
)
as
    set nocount on;

    declare @STARTDATE datetime;
    declare @ENDDATE datetime;

    exec dbo.USP_APPCATALOG_GETNEWFEATURESTARTENDDATES @SHOWCODE, @STARTDATE output, @ENDDATE output;

    with xmlnamespaces ('bb_appfx_smartfield' as tns, 'bb_appfx_commontypes' as common)
    select S.ID,
           S.DISPLAYNAME,
           S.DESCRIPTION,
           S.SMARTFIELDSPECXML.value('(tns:SmartFieldSpec/@Author)[1]', 'nvarchar(500)'),
           coalesce(RT.NAME, ''),
           S.DATEADDED,
           dbo.UFN_INSTALLEDPRODUCTS_OPTIONALPRODUCTSINSTALLED(S.SMARTFIELDSPECXML.query('tns:SmartFieldSpec/common:InstalledProductList'))
    from dbo.SMARTFIELDCATALOG as S
         left join dbo.RECORDTYPE as RT on S.RECORDTYPEID = RT.ID
    where ((@STARTDATE is null) or (S.DATEADDED >= @STARTDATE)) and
          ((@ENDDATE is null) or (S.DATEADDED <= @ENDDATE)) and
          ((@RECORDTYPEID is null) or (S.RECORDTYPEID = @RECORDTYPEID)) and
          ((@INCLUDEALLPRODUCTS = 1) or (1 = dbo.UFN_INSTALLEDPRODUCTS_OPTIONALPRODUCTSINSTALLED(S.SMARTFIELDSPECXML.query('/*/common:InstalledProductList')))) and
          ((@DATAWINDOWOPEN is null) or (S.DATEADDED >= @DATAWINDOWOPEN)) and 
          ((@DATAWINDOWCLOSE is null) or (S.DATEADDED < @DATAWINDOWCLOSE))
    order by S.DATEADDED DESC