USP_DATALIST_NEWTASKS

CREATE procedure dbo.USP_DATALIST_NEWTASKS
(
    @SHOWCODE smallint = 1,
    @INCLUDEALLPRODUCTS bit = 0,
    @DATAWINDOWOPEN datetime = null,
    @DATAWINDOWCLOSE datetime = null
)
as
    set nocount on;

    declare @STARTDATE datetime;
    declare @ENDDATE datetime;

    exec dbo.USP_APPCATALOG_GETNEWFEATURESTARTENDDATES @SHOWCODE, @STARTDATE output, @ENDDATE output;

    with xmlnamespaces ('bb_appfx_task' as tns, 'bb_appfx_commontypes' as common)
    select T.ID,
           T.NAME,
           T.DESCRIPTION,
           T.TASKSPECXML.value('(tns:TaskSpec/@Author)[1]', 'nvarchar(500)'),
           T.FUNCTIONALAREAID,
           (select NAME 
            from dbo.FUNCTIONALAREACATALOG as F
            where F.ID = T.FUNCTIONALAREAID) as FUNCTIONALAREA,
           T.TASKGROUP,
           T.SEQUENCE,            
           T.DATEADDED,
           dbo.UFN_INSTALLEDPRODUCTS_OPTIONALPRODUCTSINSTALLED(T.TASKSPECXML.query('tns:TaskSpec/common:InstalledProductList'))
    from dbo.TASKCATALOG as T
    where ((@STARTDATE is null) or (T.DATEADDED >= @STARTDATE)) and
          ((@ENDDATE is null) or (T.DATEADDED <= @ENDDATE)) and
          ((@INCLUDEALLPRODUCTS = 1) or (1 = dbo.UFN_INSTALLEDPRODUCTS_OPTIONALPRODUCTSINSTALLED(T.TASKSPECXML.query('/*/common:InstalledProductList')))) and
          ((@DATAWINDOWOPEN is null) or (T.DATEADDED >= @DATAWINDOWOPEN)) and 
          ((@DATAWINDOWCLOSE is null) or (T.DATEADDED < @DATAWINDOWCLOSE))
    order by T.DATEADDED DESC