USP_MKTSEGMENTLIST_UPDATESTANDARDQUERYINFO

Updates a list segment with the standard query view catalog ID created or updated during the import or duplicates process.

Parameters

Parameter	Parameter Type	Mode
@ID	uniqueidentifier	IN
@CHANGEAGENTID	uniqueidentifier	IN
@QUERYVIEWCATALOGID	uniqueidentifier	IN
@STANDARDIDSETID	uniqueidentifier	IN
@IDSETRECORDTYPEID	uniqueidentifier	IN

Definition

Copy



create procedure dbo.[USP_MKTSEGMENTLIST_UPDATESTANDARDQUERYINFO]
(
  @ID uniqueidentifier,
  @CHANGEAGENTID uniqueidentifier = null,
  @QUERYVIEWCATALOGID uniqueidentifier,
  @STANDARDIDSETID uniqueidentifier,
  @IDSETRECORDTYPEID uniqueidentifier
)
as
  set nocount on;

  declare @SEGMENTID uniqueidentifier;
  declare @CURRENTDATE datetime;

  begin try
    if @CHANGEAGENTID is null
      exec dbo.[USP_CHANGEAGENT_GETORCREATECHANGEAGENT] @CHANGEAGENTID output;

    set @CURRENTDATE = getdate();

    select
      @SEGMENTID = [SEGMENTID]
    from dbo.[MKTSEGMENTLIST]
    where [ID] = @ID;

    update dbo.[MKTSEGMENTLIST] set
      [QUERYVIEWCATALOGID] = @QUERYVIEWCATALOGID,
      [STANDARDIDSETID] = @STANDARDIDSETID,
      [IDSETRECORDTYPEID] = @IDSETRECORDTYPEID,
      [CHANGEDBYID] = @CHANGEAGENTID,
      [DATECHANGED] = @CURRENTDATE
    where [ID] = @ID;

    update dbo.[MKTSEGMENT] set
      [IDSETREGISTERID] = @STANDARDIDSETID,
      [CHANGEDBYID] = @CHANGEAGENTID,
      [DATECHANGED] = @CURRENTDATE
    where [ID] = @SEGMENTID;

    insert into dbo.[MKTSEGMENTSELECTION] (
      [ID],
      [SEGMENTID],
      [SELECTIONID],
      [ADDEDBYID],
      [CHANGEDBYID],
      [DATEADDED],
      [DATECHANGED]
    ) values (
      newid(),
      @SEGMENTID,
      @STANDARDIDSETID,
      @CHANGEAGENTID,
      @CHANGEAGENTID,
      @CURRENTDATE,
      @CURRENTDATE
    );
  end try

  begin catch
    exec dbo.[USP_RAISE_ERROR];
    return 1;
  end catch

  return 0;