USP_PROSPECTRESEARCHREQUESTCONSTITUENT_EDITEDALERT_SEND

            create procedure dbo.USP_PROSPECTRESEARCHREQUESTCONSTITUENT_EDITEDALERT_SEND (
                @CURRENTAPPUSERID uniqueidentifier,
                @PROSPECTRESEARCHREQUESTID uniqueidentifier
            ) as begin
                set nocount on;

                declare
                    @REQUESTEDBYAPPUSERID uniqueidentifier,
                    @SUBMITTEDBYAPPUSERID uniqueidentifier,
                    @ASSIGNEDTOAPPUSERID uniqueidentifier

                select
                    @REQUESTEDBYAPPUSERID = REQUESTEDBYAU.[ID],
                    @SUBMITTEDBYAPPUSERID = SUBMITTEDBYAU.[ID],
                    @ASSIGNEDTOAPPUSERID = ASSIGNEDTOAU.[ID]
                from
                    dbo.[PROSPECTRESEARCHREQUESTCONSTITUENT] PRRC
                left join
                    dbo.[PROSPECTRESEARCHREQUEST] PRR on PRR.[ID] = PRRC.[PROSPECTRESEARCHREQUESTID]
                left join
                    dbo.[APPUSER] REQUESTEDBYAU on REQUESTEDBYAU.[CONSTITUENTID] = PRR.[REQUESTEDBYID]
                left join
                    dbo.[APPUSER] SUBMITTEDBYAU on SUBMITTEDBYAU.[CONSTITUENTID] = PRR.[SUBMITTEDBYID]
                left join
                    dbo.[APPUSER] ASSIGNEDTOAU on ASSIGNEDTOAU.[CONSTITUENTID] = PRRC.[ASSIGNEDTOID]
                where
                    PRRC.[ID] = @PROSPECTRESEARCHREQUESTID;

                if @REQUESTEDBYAPPUSERID is not null and
                    (@REQUESTEDBYAPPUSERID <> @CURRENTAPPUSERID or @CURRENTAPPUSERID is null) begin
                    exec dbo.USP_ALERTTYPE_SENDTOAPPUSER 'B98A7E1E-C38E-4ae4-8BA6-EBABDBFE0E01', @REQUESTEDBYAPPUSERID, @PROSPECTRESEARCHREQUESTID;
                end

                if @SUBMITTEDBYAPPUSERID is not null and
                    (@SUBMITTEDBYAPPUSERID <> @CURRENTAPPUSERID or @CURRENTAPPUSERID is null) and
                    (@SUBMITTEDBYAPPUSERID <> @REQUESTEDBYAPPUSERID or @REQUESTEDBYAPPUSERID is null) begin
                    exec dbo.USP_ALERTTYPE_SENDTOAPPUSER 'B98A7E1E-C38E-4ae4-8BA6-EBABDBFE0E01', @SUBMITTEDBYAPPUSERID, @PROSPECTRESEARCHREQUESTID;
                end

                if @ASSIGNEDTOAPPUSERID is not null and
                    (@ASSIGNEDTOAPPUSERID <> @CURRENTAPPUSERID or @CURRENTAPPUSERID is null) and
                    (@ASSIGNEDTOAPPUSERID <> @REQUESTEDBYAPPUSERID or @REQUESTEDBYAPPUSERID is null) and
                    (@ASSIGNEDTOAPPUSERID <> @SUBMITTEDBYAPPUSERID or @SUBMITTEDBYAPPUSERID is null) begin
                    exec dbo.USP_ALERTTYPE_SENDTOAPPUSER 'B98A7E1E-C38E-4ae4-8BA6-EBABDBFE0E01', @ASSIGNEDTOAPPUSERID, @PROSPECTRESEARCHREQUESTID;
                end

                return 0;
            end