USP_RECOGNITIONCREDIT_ADDDEFAULTSFORMGSPLITS

            CREATE procedure dbo.USP_RECOGNITIONCREDIT_ADDDEFAULTSFORMGSPLITS
            (
                @SPLITS xml,
                @DONORID uniqueidentifier,
                @DONATIONDATE datetime,
                @RECOGNITIONCREDITTYPEID uniqueidentifier,
                @CHANGEAGENTID uniqueidentifier = null,
                @CURRENTDATE datetime = null
            )
            as
                set nocount on;

                if @CHANGEAGENTID is null
                    exec dbo.USP_CHANGEAGENT_GETORCREATECHANGEAGENT @CHANGEAGENTID output;

                if @CURRENTDATE is null
                    set @CURRENTDATE = getdate();

                --Set currency parameters for backwards compatibility

                declare @ORGANIZATIONCURRENCYID uniqueidentifier;
                set @ORGANIZATIONCURRENCYID = dbo.UFN_CURRENCY_GETORGANIZATIONCURRENCY();

                begin try

                    insert into REVENUERECOGNITION
                    (
                        ID, 
                        REVENUESPLITID,
                        CONSTITUENTID,
                        AMOUNT,
                        EFFECTIVEDATE,
                        REVENUERECOGNITIONTYPECODEID, 
                        ADDEDBYID, 
                        CHANGEDBYID, 
                        DATEADDED,
                        DATECHANGED,
                        BASECURRENCYID,
                        ORGANIZATIONAMOUNT,
                        ORGANIZATIONEXCHANGERATEID
                    )
                    select
                        newid(),
                        ID,
                        @DONORID,
                        AMOUNT,
                        @DONATIONDATE,
                        @RECOGNITIONCREDITTYPEID,
                        @CHANGEAGENTID,
                        @CHANGEAGENTID,
                        @CURRENTDATE,
                        @CURRENTDATE,

                        --Set currency parameters for backwards compatibility

                        case
                            when BASECURRENCYID is null then
                                @ORGANIZATIONCURRENCYID
                            else
                                BASECURRENCYID
                        end,

                        case
                            when BASECURRENCYID is null then
                                AMOUNT
                            else
                                ORGANIZATIONAMOUNT
                        end,

                        case
                            when BASECURRENCYID is null then
                                null
                            else
                                ORGANIZATIONEXCHANGERATEID
                        end
                    from dbo.UFN_REVENUE_GETSPLITS_2_FROMITEMLISTXML(@SPLITS)

                end try

                begin catch
                    exec dbo.USP_RAISE_ERROR;
                    return 1;
                end catch

                return 0;