USP_REPORT_APPEALPROFILE_GIFTHISTORY

CREATE procedure dbo.[USP_REPORT_APPEALPROFILE_GIFTHISTORY]
(
  @APPEALID uniqueidentifier = null,
  @SHOW bit = null,
  @CURRENTAPPUSERID uniqueidentifier = null,
  @REPORTUSERID nvarchar(128) = null,
  @CURRENCYCODE tinyint = null,
  @ALTREPORTUSERID nvarchar(128) = null
)
as
  begin
    set nocount on;

    declare @CURRENCYID uniqueidentifier;
    declare @ORGANIZATIONCURRENCYID uniqueidentifier;
    declare @CURRENCYISO nvarchar(3);
    declare @CURRENCYDECIMALDIGITS tinyint;
    declare @CURRENCYSYMBOL nvarchar(5);
    declare @CURRENCYSYMBOLDISPLAYSETTINGCODE tinyint;
    declare @CURRENCYROUNDINGTYPECODE tinyint;
    declare @ORGANIZATIONAMOUNTORIGINCODE tinyint;

    begin try
      if @SHOW = 1
        begin
          exec dbo.[USP_REPORT_APPEALPROFILE_REVENUEPARAMETERS]
            @APPEALID,
            @REPORTUSERID,
            @ALTREPORTUSERID,
            @CURRENCYCODE,
            @CURRENTAPPUSERID output,
            @CURRENCYID output,
            @ORGANIZATIONCURRENCYID output,
            @CURRENCYISO output,
            @CURRENCYDECIMALDIGITS output,
            @CURRENCYSYMBOL output,
            @CURRENCYSYMBOLDISPLAYSETTINGCODE output,
            @CURRENCYROUNDINGTYPECODE output,
            @ORGANIZATIONAMOUNTORIGINCODE output;

          select 
            'http://www.blackbaud.com/REVENUEID?REVENUEID=' + convert(nvarchar(36), [REVENUE].[REVENUEID]) as [REVENUEID],
            [CONSTITUENT].[KEYNAME],
            [CONSTITUENT].[FIRSTNAME],
            [CONSTITUENT].[NAME],
            [REVENUE].[DATE],
            [REVENUE].[AMOUNT],
            [REVENUE].[BALANCE],
            [FT].[TYPE] as [TRANSACTIONTYPE],
            [REVENUE].[DESIGNATION],
            [REVENUE].[TRANSACTIONAMOUNT],
            [REVENUESPLIT].[APPLICATION] + case REVENUESPLIT.APPLICATIONCODE when 3 then ' payment' else '' end as [APPLICATION],
            'http://www.blackbaud.com/DESIGNATIONID?DESIGNATIONID=' + convert(nvarchar(36), [REVENUE].[DESIGNATIONID]) as [DESIGNATIONID],
            @CURRENCYID as [CURRENCYID],
            @CURRENCYISO as [CURRENCYISO],
            @CURRENCYDECIMALDIGITS as [CURRENCYDECIMALDIGITS],
            @CURRENCYSYMBOL as [CURRENCYSYMBOL],
            @CURRENCYSYMBOLDISPLAYSETTINGCODE as [CURRENCYSYMBOLDISPLAYSETTINGCODE]
          from dbo.[UFN_REPORT_APPEALPROFILE_REVENUE] (
            @CURRENTAPPUSERID,
            @CURRENCYCODE,
            @CURRENCYID,
            @ORGANIZATIONCURRENCYID,
            @CURRENCYISO,
            @CURRENCYDECIMALDIGITS,
            @CURRENCYSYMBOL,
            @CURRENCYSYMBOLDISPLAYSETTINGCODE,
            @CURRENCYROUNDINGTYPECODE,
            @ORGANIZATIONAMOUNTORIGINCODE) as [REVENUE]
          inner join dbo.[FINANCIALTRANSACTION] as [FT] on [FT].[ID] = [REVENUE].[REVENUEID]
          inner join dbo.[CONSTITUENT] on [CONSTITUENT].[ID] = [FT].[CONSTITUENTID]
          inner join dbo.[REVENUESPLIT_EXT] as [REVENUESPLIT] on [REVENUESPLIT].[ID] = [REVENUE].[REVENUESPLITID]
          where [REVENUE].[APPEALID] = @APPEALID
        end
    end try

    begin catch
      exec dbo.[USP_RAISE_ERROR];
      return 1;
    end catch

    return 0;
  end