USP_REPORT_DECAPITALIZATIONFUND

                create procedure dbo.USP_REPORT_DECAPITALIZATIONFUND
                (
                    @ID uniqueidentifier = null,
                    @CURRENCYCODE tinyint = 1
                )

                as
                    set nocount on;

                    if @CURRENCYCODE = 0
                        select
                            dbo.UFN_DATE_FROMFUZZYDATE(DESIGNATIONLEVELDECAPITALIZATION.APPROVALDATE) as APPROVALDATE,
                            dbo.UFN_CONSTITUENT_BUILDNAME(DESIGNATIONLEVELDECAPITALIZATION.APPROVEDBYID) as APPROVEDBY,
                            DESIGNATION.NAME as ACCOUNT,
                            DESIGNATIONLEVELDECAPITALIZATION.AMOUNT,
                            DESIGNATIONLEVELDECAPITALIZATION.RATIONALE,
                            CURRENCYPROPERTIES.ID as CURRENCYID,
                            CURRENCYPROPERTIES.ISO4217 as CURRENCYISO,
                            CURRENCYPROPERTIES.DECIMALDIGITS as CURRENCYDECIMALDIGITS,
                            CURRENCYPROPERTIES.CURRENCYSYMBOL as CURRENCYSYMBOL,
                            CURRENCYPROPERTIES.SYMBOLDISPLAYSETTINGCODE as CURRENCYSYMBOLDISPLAYSETTINGCODE
                        from
                            dbo.DESIGNATIONLEVELDECAPITALIZATION
                            left outer join dbo.DESIGNATION on DESIGNATION.ID = DESIGNATIONLEVELDECAPITALIZATION.ACCOUNTID
                            outer apply dbo.UFN_CURRENCY_GETPROPERTIES(DESIGNATIONLEVELDECAPITALIZATION.BASECURRENCYID) CURRENCYPROPERTIES
                        where @ID = DESIGNATIONLEVELDECAPITALIZATION.DESIGNATIONLEVELID
                        order by
                            DESIGNATIONLEVELDECAPITALIZATION.APPROVALDATE desc;
                    else
                    begin
                        declare @CURRENCYID uniqueidentifier;
                        declare @CURRENCYISO nvarchar(3);
                        declare @CURRENCYDECIMALDIGITS tinyint;
                        declare @CURRENCYSYMBOL nvarchar(5);
                        declare @CURRENCYSYMBOLDISPLAYSETTINGCODE tinyint;

                        set @CURRENCYID = dbo.UFN_CURRENCY_GETORGANIZATIONCURRENCY();

                        select
                            @CURRENCYISO = ISO4217,
                            @CURRENCYDECIMALDIGITS = DECIMALDIGITS,
                            @CURRENCYSYMBOL = CURRENCYSYMBOL,
                            @CURRENCYSYMBOLDISPLAYSETTINGCODE = SYMBOLDISPLAYSETTINGCODE
                        from dbo.CURRENCY where ID = @CURRENCYID;

                        select
                            dbo.UFN_DATE_FROMFUZZYDATE(DESIGNATIONLEVELDECAPITALIZATION.APPROVALDATE) as APPROVALDATE,
                            dbo.UFN_CONSTITUENT_BUILDNAME(DESIGNATIONLEVELDECAPITALIZATION.APPROVEDBYID) as APPROVEDBY,
                            DESIGNATION.NAME as ACCOUNT,
                            DESIGNATIONLEVELDECAPITALIZATION.ORGANIZATIONAMOUNT as AMOUNT,
                            DESIGNATIONLEVELDECAPITALIZATION.RATIONALE,
                            @CURRENCYID as CURRENCYID,
                            @CURRENCYISO as CURRENCYISO,
                            @CURRENCYDECIMALDIGITS as CURRENCYDECIMALDIGITS,
                            @CURRENCYSYMBOL as CURRENCYSYMBOL,
                            @CURRENCYSYMBOLDISPLAYSETTINGCODE as CURRENCYSYMBOLDISPLAYSETTINGCODE
                        from
                            dbo.DESIGNATIONLEVELDECAPITALIZATION
                            left outer join dbo.DESIGNATION on DESIGNATION.ID = DESIGNATIONLEVELDECAPITALIZATION.ACCOUNTID
                        where @ID = DESIGNATIONLEVELDECAPITALIZATION.DESIGNATIONLEVELID
                        order by
                            DESIGNATIONLEVELDECAPITALIZATION.APPROVALDATE desc;
                    end