USP_REPORT_DEFAULTITEMIZEDRECEIPT_GETPAYMENTINFORMATION

create procedure [dbo].[USP_REPORT_DEFAULTITEMIZEDRECEIPT_GETPAYMENTINFORMATION]
(
    @ORDERID uniqueidentifier
)
as
    set nocount on;
    set transaction isolation level read uncommitted;

    select 
        SALESORDERPAYMENT.ID,
        SALESORDERPAYMENT.PAYMENTID,
        SALESORDERPAYMENT.AMOUNTTENDERED AMOUNT,
        REVENUE.DATE,
        case when REVENUEPAYMENTMETHOD.PAYMENTMETHODCODE = 0 then
            'Paid Cash'
        when REVENUEPAYMENTMETHOD.PAYMENTMETHODCODE = 1 then
            'Paid Check'
        when REVENUEPAYMENTMETHOD.PAYMENTMETHODCODE = 2 then
            'Paid ' + dbo.UFN_CREDITTYPECODE_GETDESCRIPTION(CREDITTYPECODEID)
        when REVENUEPAYMENTMETHOD.PAYMENTMETHODCODE = 10 then
            'Paid ' + dbo.UFN_OTHERPAYMENTMETHODCODE_GETDESCRIPTION(OTHERPAYMENTMETHODCODEID)
        end    PAYMENTTYPE,
        case when REVENUEPAYMENTMETHOD.PAYMENTMETHODCODE = 0 then
            ''
        when REVENUEPAYMENTMETHOD.PAYMENTMETHODCODE = 1 then
            CHECKPAYMENTMETHODDETAIL.CHECKNUMBER
        when REVENUEPAYMENTMETHOD.PAYMENTMETHODCODE = 2 then
            '************' + CREDITCARDPAYMENTMETHODDETAIL.CREDITCARDPARTIALNUMBER
        when REVENUEPAYMENTMETHOD.PAYMENTMETHODCODE = 10 then
            ''
        end    PAYMENTTYPEDETAIL,
        case when REVENUEPAYMENTMETHOD.PAYMENTMETHODCODE = 0 then
            3
        when REVENUEPAYMENTMETHOD.PAYMENTMETHODCODE = 1 then
            0
        when REVENUEPAYMENTMETHOD.PAYMENTMETHODCODE = 2 then
            1
        when REVENUEPAYMENTMETHOD.PAYMENTMETHODCODE = 10 then
            2
        end    SORTFIELD                                                                        
    from dbo.REVENUE
    inner join dbo.REVENUEPAYMENTMETHOD on REVENUE.ID = REVENUEPAYMENTMETHOD.REVENUEID
    left outer join dbo.CHECKPAYMENTMETHODDETAIL on
        REVENUEPAYMENTMETHOD.PAYMENTMETHODCODE = 1 and
        CHECKPAYMENTMETHODDETAIL.ID = REVENUEPAYMENTMETHOD.ID
    left outer join dbo.CREDITCARDPAYMENTMETHODDETAIL on
        REVENUEPAYMENTMETHOD.PAYMENTMETHODCODE = 2 and
        CREDITCARDPAYMENTMETHODDETAIL.ID = REVENUEPAYMENTMETHOD.ID
    left outer join dbo.OTHERPAYMENTMETHODDETAIL on
        REVENUEPAYMENTMETHOD.PAYMENTMETHODCODE = 10 and
        OTHERPAYMENTMETHODDETAIL.ID = REVENUEPAYMENTMETHOD.ID
    inner join dbo.SALESORDERPAYMENT on REVENUE.ID = SALESORDERPAYMENT.PAYMENTID
    left join dbo.REVENUEPOSTED on REVENUEPOSTED.ID = REVENUE.ID
    where SALESORDERPAYMENT.SALESORDERID = @ORDERID
    order by SORTFIELD, PAYMENTTYPE, SALESORDERPAYMENT.AMOUNT

    return 0;