USP_REPORT_REVENUEBATCHEXCEPTIONREPORT_CURRENCYSUMMARY

            CREATE procedure dbo.USP_REPORT_REVENUEBATCHEXCEPTIONREPORT_CURRENCYSUMMARY
            (
                @BATCHID uniqueidentifier
            )
            as            

                set nocount on;

                declare @TABLENAME nvarchar(128);
                select @TABLENAME = dbo.UFN_BATCH_GETREPORTTABLENAME(@BATCHID, 1)


                declare @CURRENCYFIELD nvarchar(100);
                if exists(select * from INFORMATION_SCHEMA.COLUMNS where TABLE_NAME = @TABLENAME and COLUMN_NAME = 'CURRENCYID')
                    select @CURRENCYFIELD = 'CURRENCYID';
                else
                    set @CURRENCYFIELD = '''' + cast(coalesce(dbo.UFN_CURRENCY_GETORGANIZATIONCURRENCY(), '00000000-0000-0000-0000-000000000000') as nvarchar(36)) + '''';


                declare @SQLTOEXEC nvarchar(max);
                set @SQLTOEXEC = N'set nocount on;
                    with TBL_CTE as
                    (
                    select 
                        ' + @CURRENCYFIELD + ' as REVENUECURRENCYID,
                        ISPAYMENT,
                        PAYMENTAMOUNT,
                        ISPLEDGE,
                        PLEDGEAMOUNT,
                        ISRECURRINGGIFT,
                        RECURRINGGIFTAMOUNT
                    from ' + @TABLENAME + '
                    )
                    select
                        CURRENCY.ID CURRENCYID,
                        CURRENCY.NAME CURRENCYNAME,
                        sum(VIEWDATA.ISPAYMENT) as [TOTALPAYMENTCOUNT],
                        sum(VIEWDATA.PAYMENTAMOUNT) as [TOTALPAYMENTAMOUNT],
                        sum(VIEWDATA.ISPLEDGE) as [TOTALPLEDGECOUNT],
                        sum(VIEWDATA.PLEDGEAMOUNT) as [TOTALPLEDGEAMOUNT],
                        sum(VIEWDATA.ISRECURRINGGIFT) as [TOTALRECURRINGGIFTCOUNT],
                        sum(VIEWDATA.RECURRINGGIFTAMOUNT) as [TOTALRECURRINGGIFTAMOUNT],
                        CURRENCY.ISO4217,
                        CURRENCY.DECIMALDIGITS,
                        CURRENCY.CURRENCYSYMBOL,
                        CURRENCY.SYMBOLDISPLAYSETTINGCODE
                    from TBL_CTE VIEWDATA
                    inner join dbo.CURRENCY on CURRENCY.ID = VIEWDATA.REVENUECURRENCYID
                    group by CURRENCY.ID,CURRENCY.NAME,CURRENCY.ISO4217,CURRENCY.DECIMALDIGITS,CURRENCY.CURRENCYSYMBOL,CURRENCY.SYMBOLDISPLAYSETTINGCODE
                    order by CURRENCYNAME;';

                exec sp_executesql @SQLTOEXEC;