USP_REVENUE_GETPROPERTYDETAILGLDISTRIBUTION_CUSTOMUPDATEFROMXML_2

            CREATE procedure dbo.USP_REVENUE_GETPROPERTYDETAILGLDISTRIBUTION_CUSTOMUPDATEFROMXML_2
            (
                @PROPERTYDETAILID uniqueidentifier,
                @XML xml,
                @POSTDATE datetime,
                @CHANGEAGENTID uniqueidentifier = null,
                @CHANGEDATE datetime = null
            )

            as

            set nocount on;

            if @CHANGEAGENTID is null
                exec USP_CHANGEAGENT_GETORCREATECHANGEAGENT @CHANGEAGENTID output

            if @CHANGEDATE is null 
                set @CHANGEDATE = getdate()

            -- build a temporary table containing the values from the XML

            declare @TempTbl table (
                [ACCOUNT] nvarchar(100),
                [AMOUNT] money,
                [GLPAYMENTMETHODREVENUETYPEMAPPINGID] uniqueidentifier,
                [ID] uniqueidentifier,
                [PROJECT] nvarchar(100),
                [REFERENCE] nvarchar(100),
                [TRANSACTIONTYPECODE] tinyint,
                [ORGANIZATIONAMOUNT] money,
                [BASECURRENCYID] uniqueidentifier,
                [TRANSACTIONAMOUNT] money,
                [TRANSACTIONCURRENCYID] uniqueidentifier,
                [BASEEXCHANGERATEID] uniqueidentifier,
                [ORGANIZATIONEXCHANGERATEID] uniqueidentifier
            )

            insert into @TempTbl select 
                [ACCOUNT],
                [AMOUNT],
                [GLPAYMENTMETHODREVENUETYPEMAPPINGID],
                [ID],
                [PROJECT],
                [REFERENCE],
                [TRANSACTIONTYPECODE],
                [ORGANIZATIONAMOUNT],
                [BASECURRENCYID],
                [TRANSACTIONAMOUNT],
                [TRANSACTIONCURRENCYID],
                [BASEEXCHANGERATEID],
                [ORGANIZATIONEXCHANGERATEID]
            from dbo.UFN_REVENUE_GETPROPERTYDETAILGLDISTRIBUTION_FROMITEMLISTXML(@XML)

            declare @REVENUEID uniqueidentifier;

            select @REVENUEID = REVENUEID from REVENUEPAYMENTMETHOD where ID = @PROPERTYDETAILID;

            if @REVENUEID is null  
                select top 1 
                    @REVENUEID = PROPERTYDETAILGLDISTRIBUTION.REVENUEID
                from 
                    @TempTbl as [temp]
                inner join
                    dbo.PROPERTYDETAILGLDISTRIBUTION on [temp].ID = PROPERTYDETAILGLDISTRIBUTION.ID
                inner join 
                    dbo.GLTRANSACTION on PROPERTYDETAILGLDISTRIBUTION.GLTRANSACTIONID = GLTRANSACTION.ID;

            update @TempTbl set ID = newid() where (ID is null) or (ID = '00000000-0000-0000-0000-000000000000');

            if @@Error <> 0
                return 1;

            declare @contextCache varbinary(128);
            declare @e int;

            -- cache current context information 

            set @contextCache = CONTEXT_INFO();

            -- set CONTEXT_INFO to @CHANGEAGENTID 

            if not @CHANGEAGENTID is null
                set CONTEXT_INFO @CHANGEAGENTID;

            -- delete any items that no longer exist in the XML table

            delete from dbo.[PROPERTYDETAILGLDISTRIBUTION] where [PROPERTYDETAILGLDISTRIBUTION].ID in 
                (select ID from dbo.UFN_REVENUE_GETPROPERTYDETAILGLDISTRIBUTION
                (
                    @PROPERTYDETAILID
                )
                EXCEPT select ID from @TempTbl)    

            select @e=@@error;

            -- reset CONTEXT_INFO to previous value 

            if not @contextCache is null
                set CONTEXT_INFO @contextCache;

            if @e <> 0
                return 2;

            -- update the items that exist in the XML table and the db

            merge into  dbo.[PROPERTYDETAILGLDISTRIBUTION]
            using  @TempTbl as [temp] on [PROPERTYDETAILGLDISTRIBUTION].ID = [temp].ID
            when matched 
                and (
                    ([PROPERTYDETAILGLDISTRIBUTION].[ACCOUNT]<>temp.[ACCOUNT]) or 
                    ([PROPERTYDETAILGLDISTRIBUTION].[ACCOUNT] is null and temp.[ACCOUNT] is not null) or 
                    ([PROPERTYDETAILGLDISTRIBUTION].[ACCOUNT] is not null and temp.[ACCOUNT] is null) or 
                    ([PROPERTYDETAILGLDISTRIBUTION].[AMOUNT]<>temp.[AMOUNT]) or 
                    ([PROPERTYDETAILGLDISTRIBUTION].[AMOUNT] is null and temp.[AMOUNT] is not null) or 
                    ([PROPERTYDETAILGLDISTRIBUTION].[AMOUNT] is not null and temp.[AMOUNT] is null) or 
                    ([PROPERTYDETAILGLDISTRIBUTION].[GLPAYMENTMETHODREVENUETYPEMAPPINGID]<>temp.[GLPAYMENTMETHODREVENUETYPEMAPPINGID]) or 
                    ([PROPERTYDETAILGLDISTRIBUTION].[GLPAYMENTMETHODREVENUETYPEMAPPINGID] is null and temp.[GLPAYMENTMETHODREVENUETYPEMAPPINGID] is not null) or 
                    ([PROPERTYDETAILGLDISTRIBUTION].[GLPAYMENTMETHODREVENUETYPEMAPPINGID] is not null and temp.[GLPAYMENTMETHODREVENUETYPEMAPPINGID] is null) or 
                    ([PROPERTYDETAILGLDISTRIBUTION].[ID]<>temp.[ID]) or 
                    ([PROPERTYDETAILGLDISTRIBUTION].[ID] is null and temp.[ID] is not null) or 
                    ([PROPERTYDETAILGLDISTRIBUTION].[ID] is not null and temp.[ID] is null) or 
                    ([PROPERTYDETAILGLDISTRIBUTION].[PROJECT]<>temp.[PROJECT]) or 
                    ([PROPERTYDETAILGLDISTRIBUTION].[PROJECT] is null and temp.[PROJECT] is not null) or 
                    ([PROPERTYDETAILGLDISTRIBUTION].[PROJECT] is not null and temp.[PROJECT] is null) or 
                    ([PROPERTYDETAILGLDISTRIBUTION].[REFERENCE]<>temp.[REFERENCE]) or 
                    ([PROPERTYDETAILGLDISTRIBUTION].[REFERENCE] is null and temp.[REFERENCE] is not null) or 
                    ([PROPERTYDETAILGLDISTRIBUTION].[REFERENCE] is not null and temp.[REFERENCE] is null) or 
                    ([PROPERTYDETAILGLDISTRIBUTION].[TRANSACTIONTYPECODE]<>temp.[TRANSACTIONTYPECODE]) or 
                    ([PROPERTYDETAILGLDISTRIBUTION].[TRANSACTIONTYPECODE] is null and temp.[TRANSACTIONTYPECODE] is not null) or 
                    ([PROPERTYDETAILGLDISTRIBUTION].[TRANSACTIONTYPECODE] is not null and temp.[TRANSACTIONTYPECODE] is null) or
                    ([PROPERTYDETAILGLDISTRIBUTION].ORGANIZATIONAMOUNT <> temp.ORGANIZATIONAMOUNT) or
                    ([PROPERTYDETAILGLDISTRIBUTION].TRANSACTIONAMOUNT <> temp.TRANSACTIONAMOUNT) or
                    ([PROPERTYDETAILGLDISTRIBUTION].TRANSACTIONCURRENCYID <> temp.TRANSACTIONCURRENCYID) or
                    ([PROPERTYDETAILGLDISTRIBUTION].BASECURRENCYID <> temp.BASECURRENCYID) or 
                    ([PROPERTYDETAILGLDISTRIBUTION].[BASEEXCHANGERATEID]<>temp.[BASEEXCHANGERATEID]) or 
                    ([PROPERTYDETAILGLDISTRIBUTION].[BASEEXCHANGERATEID] is null and temp.[BASEEXCHANGERATEID] is not null) or 
                    ([PROPERTYDETAILGLDISTRIBUTION].[BASEEXCHANGERATEID] is not null and temp.[BASEEXCHANGERATEID] is null) or 
                    ([PROPERTYDETAILGLDISTRIBUTION].[ORGANIZATIONEXCHANGERATEID]<>temp.[ORGANIZATIONEXCHANGERATEID]) or 
                    ([PROPERTYDETAILGLDISTRIBUTION].[ORGANIZATIONEXCHANGERATEID] is null and temp.[ORGANIZATIONEXCHANGERATEID] is not null) or 
                    ([PROPERTYDETAILGLDISTRIBUTION].[ORGANIZATIONEXCHANGERATEID] is not null and temp.[ORGANIZATIONEXCHANGERATEID] is null)                
                    )
            then update 
                set
                    [PROPERTYDETAILGLDISTRIBUTION].[ACCOUNT]=temp.[ACCOUNT],
                    [PROPERTYDETAILGLDISTRIBUTION].[AMOUNT]=temp.[AMOUNT],
                    [PROPERTYDETAILGLDISTRIBUTION].[GLPAYMENTMETHODREVENUETYPEMAPPINGID]=temp.[GLPAYMENTMETHODREVENUETYPEMAPPINGID],
                    [PROPERTYDETAILGLDISTRIBUTION].[ID]=temp.[ID],
                    [PROPERTYDETAILGLDISTRIBUTION].[PROJECT]=temp.[PROJECT],
                    [PROPERTYDETAILGLDISTRIBUTION].[REFERENCE]=temp.[REFERENCE],
                    [PROPERTYDETAILGLDISTRIBUTION].[TRANSACTIONTYPECODE]=temp.[TRANSACTIONTYPECODE],
                    [PROPERTYDETAILGLDISTRIBUTION].CHANGEDBYID = @CHANGEAGENTID,
                    [PROPERTYDETAILGLDISTRIBUTION].DATECHANGED = @CHANGEDATE,
                    [PROPERTYDETAILGLDISTRIBUTION].ORGANIZATIONAMOUNT = temp.ORGANIZATIONAMOUNT,
                    [PROPERTYDETAILGLDISTRIBUTION].BASECURRENCYID = temp.BASECURRENCYID,
                    [PROPERTYDETAILGLDISTRIBUTION].TRANSACTIONAMOUNT = temp.TRANSACTIONAMOUNT,
                    [PROPERTYDETAILGLDISTRIBUTION].TRANSACTIONCURRENCYID = temp.TRANSACTIONCURRENCYID,
                    [PROPERTYDETAILGLDISTRIBUTION].BASEEXCHANGERATEID = temp.BASEEXCHANGERATEID,
                    [PROPERTYDETAILGLDISTRIBUTION].ORGANIZATIONEXCHANGERATEID = temp.ORGANIZATIONEXCHANGERATEID;


            --Update the corresponding rows in the GLTRANSACTION table

            merge into  dbo.[GLTRANSACTION]
            using  @TempTbl as [temp] 
                inner join PROPERTYDETAILGLDISTRIBUTION on PROPERTYDETAILGLDISTRIBUTION.ID = [temp].ID
                on [GLTRANSACTION].ID = [temp].ID
            when matched 
            then update
                set 
                    GLTRANSACTION.ACCOUNT = PROPERTYDETAILGLDISTRIBUTION.ACCOUNT,
                    GLTRANSACTION.AMOUNT = PROPERTYDETAILGLDISTRIBUTION.AMOUNT,
                    GLTRANSACTION.PROJECT = PROPERTYDETAILGLDISTRIBUTION.PROJECT,
                    GLTRANSACTION.REFERENCE = PROPERTYDETAILGLDISTRIBUTION.REFERENCE,
                    GLTRANSACTION.TRANSACTIONTYPECODE = PROPERTYDETAILGLDISTRIBUTION.TRANSACTIONTYPECODE,
                    GLTRANSACTION.POSTDATE = @POSTDATE,
                    GLTRANSACTION.CHANGEDBYID = @CHANGEAGENTID,
                    GLTRANSACTION.DATECHANGED = @CHANGEDATE,
                    [GLTRANSACTION].ORGANIZATIONAMOUNT = PROPERTYDETAILGLDISTRIBUTION.ORGANIZATIONAMOUNT,
                    [GLTRANSACTION].BASECURRENCYID = PROPERTYDETAILGLDISTRIBUTION.BASECURRENCYID,
                    [GLTRANSACTION].TRANSACTIONAMOUNT = PROPERTYDETAILGLDISTRIBUTION.TRANSACTIONAMOUNT,
                    [GLTRANSACTION].TRANSACTIONCURRENCYID = PROPERTYDETAILGLDISTRIBUTION.TRANSACTIONCURRENCYID,
                    [GLTRANSACTION].BASEEXCHANGERATEID = PROPERTYDETAILGLDISTRIBUTION.BASEEXCHANGERATEID,
                    [GLTRANSACTION].ORGANIZATIONEXCHANGERATEID = PROPERTYDETAILGLDISTRIBUTION.ORGANIZATIONEXCHANGERATEID,
                    [GLTRANSACTION].GLACCOUNTID =  dbo.UFN_GLACCOUNT_GETIDFROMACCOUNTANDREVENUE(PROPERTYDETAILGLDISTRIBUTION.ACCOUNT,@REVENUEID);

            if @@Error <> 0
                return 3;    


            -- insert new items

            declare @DISTRIBUTIONS table(
                GLTRANSACTIONID uniqueidentifier,
                ACCOUNT nvarchar(100),
                AMOUNT money,
                PROJECT nvarchar(100),
                REFERENCE nvarchar(255),
                TRANSACTIONTYPECODE tinyint,
                GLPAYMENTMETHODREVENUETYPEMAPPINGID uniqueidentifier,
                PROPERTYDETAILGLDISTRIBUTIONID uniqueidentifier,
                [ORGANIZATIONAMOUNT] money,
                [BASECURRENCYID] uniqueidentifier,
                [TRANSACTIONAMOUNT] money,
                [TRANSACTIONCURRENCYID] uniqueidentifier,
                [BASEEXCHANGERATEID] uniqueidentifier,
                [ORGANIZATIONEXCHANGERATEID] uniqueidentifier
            );

            insert into @DISTRIBUTIONS(GLTRANSACTIONID, ACCOUNT, AMOUNT, PROJECT, REFERENCE, TRANSACTIONTYPECODE, GLPAYMENTMETHODREVENUETYPEMAPPINGID, PROPERTYDETAILGLDISTRIBUTIONID, [ORGANIZATIONAMOUNT], [BASECURRENCYID], [TRANSACTIONAMOUNT], [TRANSACTIONCURRENCYID], [BASEEXCHANGERATEID], [ORGANIZATIONEXCHANGERATEID])
            select 
                newid(), 
                [ACCOUNT],
                [AMOUNT],
                [PROJECT],
                [REFERENCE],
                [TRANSACTIONTYPECODE], 
                [GLPAYMENTMETHODREVENUETYPEMAPPINGID],
                [ID],
                [ORGANIZATIONAMOUNT],
                [BASECURRENCYID],
                [TRANSACTIONAMOUNT],
                [TRANSACTIONCURRENCYID],
                [BASEEXCHANGERATEID],
                [ORGANIZATIONEXCHANGERATEID]
            from @TempTbl as [temp]
            where not exists (select ID from dbo.[PROPERTYDETAILGLDISTRIBUTION] as data where data.ID = [temp].ID)

            -- Insert rows in GLTRANSACTION table

            insert into dbo.GLTRANSACTION(ID, TRANSACTIONTYPECODE, ACCOUNT, AMOUNT, PROJECT, REFERENCE, POSTDATE, JOURNAL, ADDEDBYID, CHANGEDBYID, DATEADDED, DATECHANGED, [ORGANIZATIONAMOUNT], [BASECURRENCYID], [TRANSACTIONAMOUNT], [TRANSACTIONCURRENCYID], [BASEEXCHANGERATEID], [ORGANIZATIONEXCHANGERATEID],[GLACCOUNTID])
            select
                GLTRANSACTIONID,
                TRANSACTIONTYPECODE,
                ACCOUNT,
                AMOUNT,
                PROJECT,
                REFERENCE,
                @POSTDATE,
                'Blackbaud Enterprise',
                @CHANGEAGENTID,
                @CHANGEAGENTID,
                @CHANGEDATE,
                @CHANGEDATE,
                [ORGANIZATIONAMOUNT],
                [BASECURRENCYID],
                [TRANSACTIONAMOUNT],
                [TRANSACTIONCURRENCYID],
                [BASEEXCHANGERATEID],
                [ORGANIZATIONEXCHANGERATEID],
                dbo.UFN_GLACCOUNT_GETIDFROMACCOUNTANDREVENUE([ACCOUNT],@REVENUEID)
            from 
                @DISTRIBUTIONS;

            -- Insert rows in PROPERTYDETAILGLDISTRIBUTION table

            insert into dbo.PROPERTYDETAILGLDISTRIBUTION
                (ID, PROPERTYDETAILID, REVENUEID, GLPAYMENTMETHODREVENUETYPEMAPPINGID, PROJECT, REFERENCE, AMOUNT, ACCOUNT, TRANSACTIONTYPECODE, GLTRANSACTIONID, ADDEDBYID, CHANGEDBYID, DATEADDED, DATECHANGED, [ORGANIZATIONAMOUNT], [BASECURRENCYID], [TRANSACTIONAMOUNT], [TRANSACTIONCURRENCYID], [BASEEXCHANGERATEID], [ORGANIZATIONEXCHANGERATEID])
            select
                PROPERTYDETAILGLDISTRIBUTIONID,
                @PROPERTYDETAILID,
                @REVENUEID,
                GLPAYMENTMETHODREVENUETYPEMAPPINGID,
                PROJECT,
                REFERENCE, 
                AMOUNT,
                ACCOUNT,
                TRANSACTIONTYPECODE,
                GLTRANSACTIONID,
                @CHANGEAGENTID,
                @CHANGEAGENTID,
                @CHANGEDATE,
                @CHANGEDATE,
                [ORGANIZATIONAMOUNT],
                [BASECURRENCYID],
                [TRANSACTIONAMOUNT],
                [TRANSACTIONCURRENCYID],
                [BASEEXCHANGERATEID],
                [ORGANIZATIONEXCHANGERATEID]
            from 
                @DISTRIBUTIONS;

            if @@Error <> 0
                return 4;

            return 0;