USP_SECURITY_SYSTEMROLEFEATUREFOLDER_GET_FORMS_2

CREATE procedure dbo.USP_SECURITY_SYSTEMROLEFEATUREFOLDER_GET_FORMS_2
(
  @SYSTEMROLEID uniqueidentifier,
  @ONLYASSIGNED bit = 0,
  @ONLYDISPLAYED bit = 0
)
/*
Used by the SecurityGetRoleFeaturePermTreeRequest web service
*/
as

  set nocount on;

  if @SYSTEMROLEID is null 
  begin
    raiserror('@SYSTEMROLEID is required',16,10);
    return 8;
  end;

  select
    INST.ID,
    INST.UINAME as NAME,
    TEMP.SECURITYUIFOLDER,
    TEMP.DESCRIPTION,
    TEMP.MODE,
    PERM.ID as PERMISSIONID,
    PERM.GRANTORDENY
  from 
    dbo.V_INSTALLED_DATAFORMTEMPLATECATALOG as TEMP
  inner join 
    dbo.DATAFORMINSTANCECATALOG as INST on INST.DATAFORMTEMPLATECATALOGID = TEMP.ID
  left join
    dbo.SYSTEMROLEPERM_DATAFORMINSTANCE as PERM on PERM.DATAFORMINSTANCECATALOGID = INST.ID and PERM.SYSTEMROLEID = @SYSTEMROLEID
  where  
    (@ONLYASSIGNED = 0 or PERM.ID is not null) and
    (@ONLYDISPLAYED = 0 or TEMP.SECURITYUIDISPLAYFEATURE = 1 )
  order by 
    TEMP.SECURITYUIFOLDER, INST.UINAME;