USP_SIMPLEDATALIST_CLOSEDDRAWERSALESMETHODS

CREATE procedure dbo.USP_SIMPLEDATALIST_CLOSEDDRAWERSALESMETHODS (
    @RECONCILIATIONID uniqueidentifier
    ,@PAYMENTMEHTODCODE tinyint
)
as
    set nocount on;

    select
        T.SALESMETHODTYPECODE as VALUE
        ,T.SALESMETHODTYPE as LABEL
    from (
        select SO.SALESMETHODTYPECODE, SO.SALESMETHODTYPE
        from dbo.SALESORDERPAYMENT P 
        inner join dbo.REVENUEPAYMENTMETHOD PM on PM.REVENUEID = P.PAYMENTID
        inner join dbo.SALESORDER SO on SO.ID = P.SALESORDERID
        where P.RECONCILIATIONID = @RECONCILIATIONID and PM.PAYMENTMETHODCODE = @PAYMENTMEHTODCODE
        union all
        select SO.SALESMETHODTYPECODE, SO.SALESMETHODTYPE
        from dbo.RESERVATIONSECURITYDEPOSITPAYMENT P
        inner join dbo.REVENUEPAYMENTMETHOD PM on PM.REVENUEID = P.PAYMENTID
        inner join dbo.SALESORDER SO on SO.ID = P.RESERVATIONID
        where P.RECONCILIATIONID = @RECONCILIATIONID and PM.PAYMENTMETHODCODE = @PAYMENTMEHTODCODE
        union all
        select SO.SALESMETHODTYPECODE, SO.SALESMETHODTYPE
        from dbo.CREDITPAYMENT P
        inner join dbo.FINANCIALTRANSACTION as FT on FT.ID = P.CREDITID
        inner join dbo.CREDIT_EXT as EXT on EXT.ID = FT.ID
        left outer join dbo.SALESORDER on SALESORDER.REVENUEID = FT.PARENTID
        inner join dbo.SALESORDER SO on SO.ID = isnull(SALESORDER.ID, EXT.SALESORDERID)
        where P.RECONCILIATIONID = @RECONCILIATIONID and P.PAYMENTMETHODCODE = @PAYMENTMEHTODCODE
    ) T
    group by T.SALESMETHODTYPECODE, T.SALESMETHODTYPE
    order by T.SALESMETHODTYPE

    return 0;