USP_SIMPLEDATALIST_GETMETADATA_FORSERVICEMETHODS

                CREATE procedure [dbo].[USP_SIMPLEDATALIST_GETMETADATA_FORSERVICEMETHODS]
                (
                    @ID uniqueidentifier --Simpledatalist catalog id
                )
                as
                    set nocount on;

                    select 
                        [SDLC].[SIMPLEDATALISTSPECXML],
                        [SDLC].[PROCEDURENAME],
                        [SDLC].[IMPLEMENTATIONTYPE],
                        [SDLC].[ASSEMBLYNAME],
                        [SDLC].[CLASSNAME],
                        [SDLC].[TSLONG],
                        [TFC].[FUNCTIONNAME] as [TRANSLATION_FUNCTIONNAME],
                        [TFC].[PARAMETERDEFINITION] as [TRANSLATION_PARAMETERDEFINITION],
                        [TFC].[TSLONG] as [TRANSLATION_TSLONG],
                        cast(case when [P].[SPECIFIC_SCHEMA] is null then 0 else 1 end as bit) as [HASAPPUSER],
                        [TFC].[IMPLEMENTATIONTYPE] as [TRANSLATION_IMPLEMENTATIONTYPE],
                        [TFC].[ASSEMBLYNAME] as [TRANSLATION_ASSEMBLYNAME],
                        [TFC].[CLASSNAME] as [TRANSLATION_CLASSNAME],
                        cast(coalesce([TFC].[TRANSLATIONFUNCTIONSPEC].value('declare namespace bbspec="bb_appfx_translationfunction";/bbspec:TranslationFunctionSpec[1]/@RequiresDecryption','bit'), 0) as bit) as [TRANSLATION_REQUIRESDECRYPTION],
                        [TFC].[TRANSLATIONFUNCTIONSPEC].query('declare namespace bbspec="bb_appfx_translationfunction";declare namespace common="bb_appfx_commontypes";/bbspec:TranslationFunctionSpec[1]/bbspec:CLRTranslationFunction[1]/common:StaticParameters[1]') as [TRANSLATION_STATICPARAMETERDEFINITION]
                    from dbo.[SIMPLEDATALISTCATALOG] as [SDLC]
                    left outer join dbo.[TRANSLATIONFUNCTIONCATALOG] as [TFC] on [SDLC].[TRANSLATIONFUNCTIONCATALOGID] = [TFC].[ID]
                    left outer join [INFORMATION_SCHEMA].[PARAMETERS] as [P] on [P].[SPECIFIC_SCHEMA] = 'dbo' and [P].[SPECIFIC_NAME] = [SDLC].[PROCEDURENAME] and [P].[PARAMETER_NAME] = '@CURRENTAPPUSERID'
                    where [SDLC].[ID] = @ID;

                    return 0;