USP_SITEIMAGES_BULKDELETEFROMTRASHBIN

CREATE procedure dbo.USP_SITEIMAGES_BULKDELETEFROMTRASHBIN(@XML xml)
AS    
BEGIN

  set nocount on

    declare @SiteImageIDS table ([SiteImageID] int)
    insert into @SiteImageIDS select IDS.ID.value('.', 'int') from @XML.nodes('/SiteImages/id') IDS(ID)

    delete dbo.CMSEVERYONESECURITYPRIVS
    from dbo.CMSEVERYONESECURITYPRIVS
    inner join dbo.SiteImages on CMSEVERYONESECURITYPRIVS.SECUREDOBJECTGUID = SiteImages.Guid
    inner join @SiteImageIDS SI on SI.SiteImageID=SiteImages.ID

    delete dbo.CMSOBJETSECURITYEXCEPTION
    from dbo.CMSOBJETSECURITYEXCEPTION
    inner join dbo.SiteImages on CMSOBJETSECURITYEXCEPTION.SECUREDOBJECTGUID = SiteImages.Guid
    inner join @SiteImageIDS SI on SI.SiteImageID=SiteImages.ID

    delete dbo.SITEIMAGETAG
    from dbo.SITEIMAGETAG
    inner join @SiteImageIDS SI on SI.SiteImageID=SITEIMAGETAG.SITEIMAGEID

    delete dbo.ImageAlbum_Images
    from dbo.ImageAlbum_Images
    inner join @SiteImageIDS SI on SI.SiteImageID=ImageAlbum_Images.SITEIMAGEID

    update dbo.ImageAlbum
    set AlbumArtImageID = null
    from dbo.ImageAlbum
    inner join @SiteImageIDS SI on SI.SiteImageID=ImageAlbum.AlbumArtImageID

    delete dbo.SiteImages from dbo.SiteImages inner join @SiteImageIDS SI on SiteImages.id = SI.SiteImageID

END