USP_SYSTEMROLE_UPDATEFROMSMARTQUERYLIST

create procedure dbo.USP_SYSTEMROLE_UPDATEFROMSMARTQUERYLIST
(
    @ID uniqueidentifier,
    @CHANGEAGENTID uniqueidentifier,
    @CHANGEDATE datetime,
    @SMARTQUERYLIST xml = null,
    @SMARTQUERYLIST_DELETED xml = null
)
as
begin

    if @CHANGEAGENTID is null  
        exec dbo.USP_CHANGEAGENT_GETORCREATECHANGEAGENT @CHANGEAGENTID output;

    if @CHANGEDATE is null
        set @CHANGEDATE = getdate();

    if @SMARTQUERYLIST is not null
    begin

        declare @SMARTQUERYTABLE table
        (
            ID uniqueidentifier,
            SMARTQUERYCATALOGID uniqueidentifier,
            GRANTORDENY bit
        )
        insert into @SMARTQUERYTABLE
        select
            T.c.value('(ID)[1]','uniqueidentifier') AS 'ID',
            T.c.value('(SMARTQUERYCATALOGID)[1]','uniqueidentifier') AS 'SMARTQUERYCATALOGID',
            T.c.value('(GRANTORDENY)[1]','bit') AS 'GRANTORDENY'
        from @SMARTQUERYLIST.nodes('/SMARTQUERYLIST/ITEM') T(c)

        insert into dbo.SYSTEMROLEPERM_SMARTQUERY 
        (
            SYSTEMROLEID,
            GRANTORDENY,
            ID,
            SMARTQUERYCATALOGID,
            ADDEDBYID,
            CHANGEDBYID,
            DATEADDED,
            DATECHANGED
        )
        select 
            @ID,
            GRANTORDENY,
            ID,
            SMARTQUERYCATALOGID,
            @CHANGEAGENTID,
            @CHANGEAGENTID,
            @CHANGEDATE,
            @CHANGEDATE
        from @SMARTQUERYTABLE as [temp]
        where 
            not exists 
            (
                select ID from dbo.SYSTEMROLEPERM_SMARTQUERY as data 
                where data.ID = [temp].ID
            )

        update dbo.[SYSTEMROLEPERM_SMARTQUERY] set 
            [SYSTEMROLEPERM_SMARTQUERY].GRANTORDENY = temp.GRANTORDENY,
            [SYSTEMROLEPERM_SMARTQUERY].CHANGEDBYID = @CHANGEAGENTID,
            [SYSTEMROLEPERM_SMARTQUERY].DATECHANGED = @CHANGEDATE
        from @SMARTQUERYTABLE as [temp]
        where
            [SYSTEMROLEPERM_SMARTQUERY].ID = [temp].ID and
            [SYSTEMROLEPERM_SMARTQUERY].SMARTQUERYCATALOGID = [temp].SMARTQUERYCATALOGID and
            [SYSTEMROLEPERM_SMARTQUERY].GRANTORDENY <> [temp].GRANTORDENY

    end

    if @SMARTQUERYLIST_DELETED is not null
    begin
        declare @SMARTQUERYTABLE_DELETED table
        (
            ID uniqueidentifier
        )
        insert into @SMARTQUERYTABLE_DELETED
        select
            T.c.value('(ID)[1]','uniqueidentifier') AS 'ID'
        from @SMARTQUERYLIST_DELETED.nodes('/SMARTQUERYLIST_DELETED/ITEM') T(c)


        delete from dbo.[SYSTEMROLEPERM_SMARTQUERY] 
        where 
            [SYSTEMROLEPERM_SMARTQUERY].ID in 
            (
                select ID from @SMARTQUERYTABLE_DELETED
            )

    end

end